Ce site est optimisé pour être consulté depuis un navigateur moderne dans lequel JavaScript est activé.

[BIG Tuto] Détection du client + Initialisation des cases

d4rkv4n

Hello tout le monde !

Cliquez pour révéler Cliquez pour masquer

Désolé pour le titre du topic, y'a peu de place pour faire un titre complet...

Aujourd'hui, je vais vous apprendre à créer un script complet permettant au final d'initialiser les cases de Dofus.

Ce tutoriel ce présentera en 4 parties (que je compléterai au fur et à mesure):

0/ Préparatifs

[tab][/tab]0a - Préparer les fichiers

[tab][/tab]0b - Créer une fonction de déboguage

[tab][/tab]0c - Créer une fonction pour quitter et l'attacher à un raccourci

1/ Détecter le client

[tab][/tab]1a - Récupérer la fenêtre active

[tab][/tab]1b - Récupérer la position et les mesures de la fenêtre

2/ Détecter la zone de jeu

3/ Initialiser les cases

[tab][/tab]3a - Quelques petits calculs

[tab][/tab]3b - Initialisation de quelques variables

[tab][/tab]3c - Commencer l'initialisation !

Le copier/coller du code AutoIt dans la zone de texte Cadernis ne vous envoie malheureusement pas de bonnes indentations, tabulations. N'hésitez donc pas à faire quelque chose de propre !

Bon, n'attendons plus, allons-y !

[tab]0/- PREPARATIFS[/tab]

[tab][/tab][tab][/tab]0a - Préparer les fichiers

Commençons par le commencement. Au cours de ce tutoriel, nous ne travaillerons qu'avec deux fichiers. Vous pourrez séparer vous-même certaines fonctions par la suite, mais je laisse tout dans deux fichiers pour que ça soit plus simple lors du partage.

Nous n'aurons donc que deux fichiers. J'ai nommé le premier ClientDetection.au3, le second InitializeCases.au3.

Créez donc ces deux fichiers, et laisser-les vierges pour le moment.

[tab][/tab][tab][/tab]0b - Créer une fonction de débogage

On y est, nous allons enfin commencer à taper du code ! :ugeek:

Cette fonction sera importante pour vérifier que tout aille au mieux.

Donc, placez-vous dans le fichier ClientDetection.au3.

Nous créons une variable globale $bDebug pour savoir si les fonctions de débogage doivent être exécutées ou non.

Commençons par ce code. :


Global $bDebug         = True, _
	   $bDebug_Console = True

Func Debug($sMessage)
;    Le code viendra se placer ici...
EndFunc

$sMessage sera notre paramètre, c'est ce qui sera affiché lorsque nous appellerons la fonction.

Nous voulons ensuite vérifier si la variable $bDebug est sur True, et si c'est le cas écrire dans la console.


Func Debug($sMessage)
	Switch $bDebug
		Case True
			Switch $bDebug_Console
				Case True
					ConsoleWrite($sMessage)
			EndSwitch
	EndSwitch
EndFunc

[tab][/tab]C'est bien beau tout ça, mais si c'est juste pour faire un ConsoleWrite, on n'a pas besoin de cette fonction !

Et bien oui elle sera utile ! Premièrement parce qu'on n'aura pas besoin de mettre des If $bDebug Then à chaque fois que nous voulons déboguer, ensuite parce que nous allons mettre en forme :


Switch $bDebug_Console
	Case True
		ConsoleWrite("->=======================================================================" & @LF)
		ConsoleWrite($sMessage & @LF)
		ConsoleWrite("->=======================================================================" & @LF & @LF)
EndSwitch

Maintenant, chaque information à afficher sera entourée d'un "cadre" orange, et fera des retours à la ligne automatiques. Testons tout ça !


Debug("Je suis un test de débogage")
Debug("Han chanceux ! Et moi aussi, nah !")
Debug("Bon arrêtez de vous la péter, moi je suis un débogage multiligne !" & @LF & "Vous voyez ! Haha")

C'est à ajouter après la définition des variables, mais avant la définition de la fonction.

Ca nous retourne :

->=======================================================================
Je suis un test de débogage
->=======================================================================
->=======================================================================
Han chanceux ! Et moi aussi, nah !
->=======================================================================
->=======================================================================
Bon arrêtez de vous la péter, moi je suis un débogage multiligne !
Vous voyez ! Haha
->=======================================================================

Implémentons ça avec une dernière chose maintenant : une TrayTip qui affichera le message, au cas où vous n'avez pas la console d'AutoIt sous les yeux :


Switch $bDebug_Tray
	Case True
		TrayTip("DEBUG", $sMessage, 2)
EndSwitch

Bien sûr, ajoutez $bDebug_Tray = True dans l'initialisation des variables. Le code complet du fichier ClientDetection.au3 à ce stade :

Cliquez pour révéler Cliquez pour masquer


Global $bDebug         = True, _
	   $bDebug_Console = True, _
	   $bDebug_Tray    = True

Debug("Je suis un test de débogage")
Debug("Han chanceux ! Et moi aussi, nah !")
Debug("Bon arrêtez de vous la péter, moi je suis un débogage multiligne !" & @LF & "Vous voyez ! Haha")

Func Debug($sMessage)
	Switch $bDebug
		Case True
			Switch $bDebug_Console
				Case True
					ConsoleWrite("->=======================================================================" & @LF)
					ConsoleWrite($sMessage & @LF)
					ConsoleWrite("->=======================================================================" & @LF & @LF)
			EndSwitch

			Switch $bDebug_Tray
				Case True
					TrayTip("DEBUG", $sMessage, 2)
			EndSwitch
	EndSwitch
EndFunc

[tab][/tab][tab][/tab]0c - Créer une fonction pour quitter et l'attacher à un raccourci

Cette partie sera courte. Cette fonction nous sera utile parce que nous n'avons pas de GUI. Vous pourrez l'enlever, elle ainsi que son raccourci, lorsque vous intégrerez le script entier à votre projet.

La fonction ne sera pas compliquée. Nous l'appellerons Quit()


Func Quit()
	Debug("ESCAPE key pressed : Exiting")
	Sleep(1500)
	Exit
EndFunc

J'aime laisser un délai pour que nous puissions voir que ça quitte.

Initialisons donc le raccourci clavier. J'ai choisi la touche Echap. Tapez ce code juste dessous l'initialisation des variables :


HotKeySet("{ESC}", "Quit")

Finalement, créons une boucle, qui laissera le programme ouvert même après ses actions. C'est à placer après le raccourci :


While 1
	Sleep(250)
WEnd

Supprimez les Debug(), ils ne s'exécuteront plus, et nous n'en avons plus besoin.

Voici le code après tout ça :

Cliquez pour révéler Cliquez pour masquer


Global $bDebug         = True, _
	   $bDebug_Console = True, _
	   $bDebug_Tray    = True

HotKeySet("{ESC}", "Quit")

While 1
	Sleep(250)
WEnd

Func Debug($sMessage)
	Switch $bDebug
		Case True
			Switch $bDebug_Console
				Case True
					ConsoleWrite("->=======================================================================" & @LF)
					ConsoleWrite($sMessage & @LF)
					ConsoleWrite("->=======================================================================" & @LF & @LF)
			EndSwitch

			Switch $bDebug_Tray
				Case True
					TrayTip("DEBUG", $sMessage, 2)
			EndSwitch
	EndSwitch
EndFunc

Func Quit()
	Debug("ESCAPE key pressed : Exiting")
	Sleep(1500)
	Exit
EndFunc

Come soon pour la suite... :).

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

[tab]1/- DETECTION DU CLIENT[/tab]

[tab][/tab][tab][/tab]1a - Récupérer la fenêtre active

Nous allons créer une fonction qui, lorsque nous l'appellerons, récupérera la classe, le titre, et le handle de la fenêtre active, comparera avec ceux d'une fenêtre Dofus, et renverra le résultat.

Elle créera des variables $hHwnd_Active, $sTitle, et $sClass auxquelles nous voudrons accéder en Global. Donc ajoutez ces 3 variables dans les déclarations des variables en haut du fichier :

Global  $sTitle, _
		$hHwnd_Active, _
		$sClass

Cette fonction, je l'appellerai SetWnd :


Func SetWnd()
	$hHwnd_Active = WinGetHandle("[ACTIVE]")
	$sTitle = WinGetTitle($hHwnd_Active)
	$sClass = GetClassName($hHwnd_Active)

	Debug("Handle    => " & $hHwnd_Active & @CRLF & _
				 "Title     => " & $sTitle & @CRLF & _
				 "ClassName => " & $sClass)

	Switch $sClass
		Case "ApolloRuntimeContentWindow"
			Switch $sTitle
				Case "Dofus"
					SetError(1)
					Return $sTitle
				Case Else
					Return $hHwnd_Active
			EndSwitch
		Case Else
			SetError(2)
			Return $sClass
	EndSwitch
EndFunc

$hHwnd_Active = WinGetHandle("[ACTIVE]") récupère le handle de la fenêtre active. D'où l'intérêt d'attribuer cette fonction SetWnd à un raccourci clavier.

$sTitle = WinGetTitle($hHwnd_Active) récupère le titre de cette fenêtre active.

$sClass = GetClassName($hHwnd_Active) récupère le nom de la classe.

D'ailleurs, voici cette fonction GetClassName, que j'ai récupéré sur le net :

Cliquez pour révéler Cliquez pour masquer

Func GetClassName($hWnd)
	Local $aResult, $Length, $stText, $Text
	$Length = 4096
	$stText = DllStructCreate ("char[" & $Length & "]")
	$aResult = DllCall("User32.dll", "int", "GetClassName", "hwnd", $hWnd, "ptr", DllStructGetPtr($stText), "int", $Length)
	$Text = DllStructGetData($stText,1)
	$stText = 0
	Return $Text
EndFunc

Ensuite, on vérifie si la classe est bien "ApolloRuntimeContentWindow", qui est la classe de D. Si c'est le cas, on vérifie que le personnage est connecté en vérifiant le titre (qui ne doit donc pas être D.)

Bien sûr, remplacez les D. par le nom du jeu.

Bien, maintenant nous avons une fonction qui vérifie si tout est correct. Si la classe ne correspond pas, alors on initialise @error à 2 et on retourne la classe. Si le titre est mauvais, on initialise @error à 1, et on retourne le titre. En revanche, si tout est correct, on retourne le handle de la fenêtre, donc du jeu.

Attachons donc cette fonction à un raccourci clavier, pour tester si tout est correct. Tapez ce code sous le premier raccourci.

HotKeySet("{F2}", "SetWnd")

Lorsque vous appuyez sur F2, vous voyez, dans la console AutoIt, les informations de la fenêtre. Soit son handle, son titre, et sa classe.

[tab][/tab][tab][/tab]1b - Récupérer la position et les mesures de la fenêtre

Maintenant que nous avons le handle de la bonne fenêtre, nous devons récupérer sa position, et ses mesures, pour savoir où nous devrons cliquer, etc.

Nous appellerons cette fonction GetClientMeasures(). Nous aurons besoin d'inclure, pour son fonctionnement, deux fichiers. Tout en haut de votre fichier, tapez ces lignes :


#include <WinAPI.au3>
#include <WindowsConstants.au3>

Ensuite, créons notre fonction :

Func GetClientMeasures()
EndFunc

Premièrement, nous allons enregistrer dans une variable $aMeasures les mesures du client, et dans une autre variable $aClient_Pos la position de ce client.

$aMeasures = WinGetClientSize($sTitle)
$aClient_Pos = WinGetPos($sTitle)

$aMeasures et $aClient_Pos sont des Arrays. $aMeasures est un Array de 2 lignes. La première contient la largeur, la seconde la hauteur. Nous allons donc, pour une meilleure lisibilité pour la suite, enregistrer ces valeurs dans des variables séparées, en Global :

Global $iClient_Width  = $aMeasures[0]
Global $iClient_Height = $aMeasures[1]

Le problème maintenant, est que nous voulons récupérer la taille du client sans les bords. Il existe une fonction qui devrait nous retourner la largeur d'un bord, mais après différents tests avec différentes personnes, la valeur n'est jamais exacte. Alors je vous donne le code, mais vous devrez certainement l'adapter chez vous.

/!\ C'est très important pour la suite !!


$iBorderSize_Y 	  = _WinAPI_GetSystemMetrics($SM_CYEDGE) + 2
$iBorderSize_X 	  = _WinAPI_GetSystemMetrics($SM_CXEDGE) + 2
$iHeight_TitleBar   = _WinAPI_GetSystemMetrics($SM_CYCAPTION) + $iBorderSize_Y

C'est les " + 2" que vous devrez modifier chez vous.

Comme vous l'aurez certainement deviné, le client commence à $aClient_Pos[0]. Mais comme nous ne voulons pas des bords, alors nous pouvons en déduire qu'il commence à $aClient_Pos[0] + $iBorderSize_X. Nous devons maintenant calculer la position X de fin. Nous avons la largeur de la fenêtre, la largeur d'un bord, et la position X de départ. Donc nous pouvons en déduire que :

Global $iClient_Left = $aClient_Pos[0] + $iBorderSize_X
Global $iClient_Right = $iClient_Left + $iClient_Width

Nous devons faire la même chose pour Y. Je vous donne le code, à mon avis ça ne sera pas utile d'expliquer :

Global $iClient_Top = $aClient_Pos[1] + $iHeight_TitleBar
Global $iClient_Bottom = $iClient_Top + $iClient_Height

Je vais vous donner une fonction que j'ai créée pour que que vous voyiez le résultat. Elle dessine sur l'écran soit un rectangle, soit les diagonales, soit une ligne, soit une zone qui est un mélange d'un rectangle et de deux diagonales. Elle vérifie si la variable $bDebug_Lines est sur True ou False, donc vous devez créer cette variable. Créez-la près des autres variables de debug :

$bDebug_Lines   = True

Et donc, la fonction DrawLines au complet. Je ne l'expliquerai pas, c'est juste un utilitaire, et c'est hyper simple :

Cliquez pour révéler Cliquez pour masquer

Func DrawLines($iXS, $iYS, $iXE, $iYE, $sWhat = "line", $cColor = 0x000000)
	Switch $bDebug
		Case True
			Switch $bDebug_Lines
				Case True
					Global $hDC =      _WinAPI_GetWindowDC($sTitle) ;; On récupère le handle du context
					Global $hPen =     _WinAPI_CreatePen($PS_SOLID, 2, $cColor) ;; On crée notre Pen avec la couleur passée en paramètre
					Global $obj_orig = _WinAPI_SelectObject($hDC, $hPen) ;; On assemble le tout

					Switch $sWhat
						Case "line"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE)
						Case "zone"
							DrawLines($iXS, $iYS, $iXE, $iYE, "quad", $cColor)
							DrawLines($iXS, $iYS, $iXE, $iYE, "diagonale", $cColor)
						Case "diagonale"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE) ;; De haut à gauche jusque bas  à droite
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXS, $iYE) ;; De bas  à droite jusque haut à gauche
						Case "quad"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYS) ;; De haut à gauche jusque haut à droite   ---
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXE, $iYE) ;; De haut à droite jusque bas  à droite      |
							_WinAPI_DrawLine($hDC, $iXE, $iYE, $iXS, $iYE) ;; De bas  à droite jusque bas  à gauche   ___
							_WinAPI_DrawLine($hDC, $iXS, $iYE, $iXS, $iYS) ;; De bas  à gauche jusque haut à gauche  |
						Case "else"
							Debug("La forme que vous essayez de créer n'existe pas")
					EndSwitch
				Case False
					Debug("Le debug Lines n'est pas activé")
			EndSwitch
		Case False
			Debug("Le debug n'est pas activé")
	EndSwitch
EndFunc

Appelez donc cette fonction à la fin de GetClientMeasures() :

DrawLines($iClient_Left, $iClient_Top, $iClient_Right, $iClient_Bottom, "zone", 0x0000FF)

Vous voyez, c'est très simple. Maintenant que notre fonction GetClientMeasures est terminée, nous pouvons créer un raccourci qui l'appellera. Ajoutez donc sous les autres HotKeySet :

HotKeySet("{F3}", "GetClientMeasures")

Voilà, nous avons terminé la partie 1b ! Vous devriez avoir ce code. Si ce n'est pas le cas, c'est que vous avez dû louper quelque chose, auquel cas il vaudrait mieux que vous preniez ce code ! :P

Cliquez pour révéler Cliquez pour masquer


#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $bDebug         = True, _
	   $bDebug_Console = True, _
	   $bDebug_Tray    = True, _
	   $bDebug_Lines   = True

Global  $sTitle, _
		$hHwnd_Active, _
		$sClass

HotKeySet("{ESC}", "Quit")
HotKeySet("{F2}", "SetWnd")
HotKeySet("{F3}", "GetClientMeasures")

While 1
	Sleep(250)
WEnd

Func GetClientMeasures()
	$aMeasures = WinGetClientSize($sTitle)
	$aClient_Pos = WinGetPos($sTitle)

	Global $iClient_Width  = $aMeasures[0]
	Global $iClient_Height = $aMeasures[1]

	$iBorderSize_Y 	  = _WinAPI_GetSystemMetrics($SM_CYEDGE) + 2
	$iBorderSize_X 	  = _WinAPI_GetSystemMetrics($SM_CXEDGE) + 2
	$iHeight_TitleBar = _WinAPI_GetSystemMetrics($SM_CYCAPTION) + $iBorderSize_Y

	Global $iClient_Left = $aClient_Pos[0] + $iBorderSize_X
	Global $iClient_Right = $iClient_Left + $iClient_Width

	Global $iClient_Top = $aClient_Pos[1] + $iHeight_TitleBar
	Global $iClient_Bottom = $iClient_Top + $iClient_Height

	DrawLines($iClient_Left, $iClient_Top, $iClient_Right, $iClient_Bottom, "zone", 0x0000FF)

	Return 1
EndFunc

Func SetWnd()
	$hHwnd_Active = WinGetHandle("[ACTIVE]")
	$sTitle = WinGetTitle($hHwnd_Active)
	$sClass = GetClassName($hHwnd_Active)

	Debug("Handle    => " & $hHwnd_Active & @CRLF & _
		  "Title     => " & $sTitle & @CRLF & _
		  "ClassName => " & $sClass)

	Switch $sClass
		Case "ApolloRuntimeContentWindow"
			Switch $sTitle
				Case "Dofus"
					SetError(1)
					Return $sTitle
				Case Else
					Return $hHwnd_Active
			EndSwitch
		Case Else
			SetError(2)
			Return $sClass
	EndSwitch
EndFunc

Func GetClassName($hWnd)
	Local $aResult, $Length, $stText, $Text
	$Length = 4096
	$stText = DllStructCreate ("char[" & $Length & "]")
	$aResult = DllCall("User32.dll", "int", "GetClassName", "hwnd", $hWnd, "ptr", DllStructGetPtr($stText), "int", $Length)
	$Text = DllStructGetData($stText,1)
	$stText = 0
	Return $Text
EndFunc

Func DrawLines($iXS, $iYS, $iXE, $iYE, $sWhat = "line", $cColor = 0x000000)
	Switch $bDebug
		Case True
			Switch $bDebug_Lines
				Case True
					Global $hDC      = _WinAPI_GetWindowDC($sTitle) ;; On récupère le handle du context
					Global $hPen     = _WinAPI_CreatePen($PS_SOLID, 2, $cColor) ;; On crée notre Pen avec la couleur passée en paramètre
					Global $obj_orig = _WinAPI_SelectObject($hDC, $hPen) ;; On assemble le tout

					Switch $sWhat
						Case "line"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE)
						Case "zone"
							DrawLines($iXS, $iYS, $iXE, $iYE, "quad", $cColor)
							DrawLines($iXS, $iYS, $iXE, $iYE, "diagonale", $cColor)
						Case "diagonale"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE) ;; De haut à gauche jusque bas  à droite
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXS, $iYE) ;; De bas  à droite jusque haut à gauche
						Case "quad"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYS) ;; De haut à gauche jusque haut à droite   ---
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXE, $iYE) ;; De haut à droite jusque bas  à droite      |
							_WinAPI_DrawLine($hDC, $iXE, $iYE, $iXS, $iYE) ;; De bas  à droite jusque bas  à gauche   ___
							_WinAPI_DrawLine($hDC, $iXS, $iYE, $iXS, $iYS) ;; De bas  à gauche jusque haut à gauche  |
						Case "else"
							Debug("La forme que vous essayez de créer n'existe pas")
					EndSwitch
				Case False
					Debug("Le debug Lines n'est pas activé")
			EndSwitch
		Case False
			Debug("Le debug n'est pas activé")
	EndSwitch
EndFunc

Func Debug($sMessage)
	Switch $bDebug
		Case True
			Switch $bDebug_Console
				Case True
					ConsoleWrite("->=======================================================================" & @LF)
					ConsoleWrite($sMessage & @LF)
					ConsoleWrite("->=======================================================================" & @LF & @LF)
			EndSwitch

			Switch $bDebug_Tray
				Case True
					TrayTip("DEBUG", $sMessage, 2)
			EndSwitch
	EndSwitch
EndFunc

Func Quit()
	Debug("ESCAPE key pressed : Exiting")
	Sleep(1500)
	Exit
EndFunc

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

[tab]2/- DETECTION DE LA ZONE DE JEU[/tab]

Maintenant que nous avons détecté où se trouve notre client, et que nous avons récupéré ses mesures , nous devons récupérer celles de l'aire de jeu.

[tab]:?: L'aire de jeu, c'est quoi? :roll:[/tab]

C'est très simple. C'est chaque zone cliquable, jouable. Autrement dit, tout ce qui est dans la fenêtre excepté les bandes noires ! \o/

Commençons tout de suite par créer notre fonction GetGameAreaMeasures(). Pour que cela se fasse sans que ça prenne 3 heures, nous allons utiliser FastFind. Alors allez le télécharger sur AutoIt Script.

Vous extrayez l'archive, et ne mettez que "FastFind.dll", "FastFind64.dll", et "FastFind.au3" à côté de votre script. Les autres fichiers ne nous sont pas du tout utiles.

C'est fait? Bon alors incluez FastFind.au3 dans votre script (sous les autres includes, naturellement).

#include "FastFind.au3"

FastFind est un UDF qui utilise du C++ pour rechercher des pixels. Seulement, il ne cherche pas sur l'écran directement, mais sur un screenshot stocké dans la RAM, ce qui accélère énormément le processus.

Après cette courte explication, nous pouvons enfin créer notre fonction GetGameAreaMeasures().


Func GetGameAreaMeasures()
	FFSnapshot(0, 0, 0, 0, 1)
EndFund

FFSnapshot est donc une fonction de FastFind. Ses paramètres sont : "FFSnapShot($Left=0, $Top=0, $Right=0, $Bottom=0, $NoSnapShot=$FFDefaultSnapShot, $WindowHandle=-1)"

FFSnapshot(0, 0, 0, 0, 1) veut dire que nous créons un snapshot de la fenêtre entière, et que nous stockons ce snapshot dans la "case" 1 de son allocation à la RAM (cette dernière permet de garder plusieurs snapshots en mémoire).

Bien, maintenant, comme j'aime séparer mon code, nous allons créer une fonction GetPosition, qui prendra un argument $sPosition qui pourra être "left", "right", "top", "bottom". Let's go :


Func GetPosition($sPosition)
EndFunc

Nous devons d'abord savoir quelle position, pour ensuite embrancher. C'est simple, un Switch - Case nous fera ça :


Switch $sPosition
	Case "left"
	Case "right"
	Case "top"
	Case "bottom"
	Case Else
EndSwitch

Que devrions-nous mettre dans ces Case pour que nous sachions où commence la zone? C'est simple, commençons par la gauche. Nous avons la position du client de départ, et celle de fin. Nous devons donc chercher entre $iClient_Left et $iClient_Right. Donc :


Case "left"
	For $i = $iClient_Left To $iClient_Right
		;; Ici, il fera ce qu'il a à faire
	Next

Jusque là tout va bien? Bon, alors maintenant nous devons capturer chaque pixel, en vérifier la couleur, et si elle est différente de #000000 (donc, les bandes noires), #FFFFFF (euh... Du blanc, on sait jamais), #FF0000 (le bleu qu'on utilisera plus tard pour le debug), et #0000FF (le rouge qu'on utilise pour le débug aussi), cela voudra dire que nous aurons trouvé la position de départ. Nous allons aussi vérifier que la couleur trouvée n'est pas la première essayée. Ca peut arriver, autant éviter.

Nous pouvons donc écrire


$cCurrent_Color_From_Left = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
If $cCurrent_Color_From_Left <> "000000" And $cCurrent_Color_From_Left <> "FFFFFF" And $cCurrent_Color_From_Left <> "FF0000" And $cCurrent_Color_From_Left <> "0000FF" And $i <> $iClient_Left Then
	Global $iGameArea_Left = $i
	ExitLoop
EndIf

Notre fonction ressemble donc maintenant à ça :


Func GetPosition($sPosition)
	Switch $sPosition
		Case "left"
			For $i = $iClient_Left To $iClient_Right
			$cCurrent_Color_From_Left = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
			If $cCurrent_Color_From_Left <> "000000" And $cCurrent_Color_From_Left <> "FFFFFF" And $cCurrent_Color_From_Left <> "FF0000" And $cCurrent_Color_From_Left <> "0000FF" And $i <> $iClient_Left Then
				Global $iGameArea_Left = $i
				ExitLoop
			EndIf
		Next

		Case "right"
		Case "top"
		Case "bottom"
		Case Else
	EndSwitch
EndFunc

Donc maintenant, implémentons cette nouvelle fonction dans GetGameAreaMeasures()


Func GetGameAreaMeasures()
	FFSnapshot(0, 0, 0, 0, 1)

	GetPosition("left")
EndFunc

Je suis sûr que vous mourrez d'impatience d'essayer !

Créons donc un raccourci clavier (encore !) pour, lors de l'appui, appeler notre nouvelle fonction (à mettre bien sûr en dessous des autres HotKeySet !)

HotKeySet("{F4}", "GetGameAreaMeasures")

Puis ajouter à la fin de notre fonction GetGameAreaMeasures() cette ligne

DrawLines($iGameArea_Left, $iClient_Top, $iGameArea_Left, $iClient_Bottom, "line", 0xFF0000)

Voilà, vous devriez avoir une jolie ligne rouge qui traverse l'écran du jeu à partir de la position de l'aire de jeu gauche. Fun hein? :).

Alors implémentons la droite maintenant. Attention, petite subtilité contrairement à la gauche. Je vais vous donner le code puis l'expliquer ;).


Case "right"
	$i = $iClient_Right - 1

	While $i > $iClient_Left
		$cCurrent_Color_From_Right = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
		If $cCurrent_Color_From_Right <> "000000" And $cCurrent_Color_From_Right <> "FFFFFF" And $cCurrent_Color_From_Right <> "FF0000" And $cCurrent_Color_From_Right <> "0000FF" And $i <> $iClient_Right Then
			Global $iGameArea_Right = $i
			ExitLoop
		EndIf
		$i -= 1
	WEnd

Vous avez remarqué la différence? Nous avons utilisé une boucle While à l'instar de tout à l'heure où nous avions utilisé une boucle For.

[tab]:?: Pourquoi ? :o[/tab]

Simplement parce que For XS To XE (comprendre XS = Position X de départ et XE = Position X de fin) est obligatoirement sous la forme For plus_petit To plus_grand. Or nous cherchons du plus grand au plus petit, donc While est la solution.

Maintenant je ne pense pas avoir à expliquer le rester de la fonction, alors je vous la donne toute finie ! Généreux hm? :lol:

Cliquez pour révéler Cliquez pour masquer


Func GetPosition($sPosition)
	Switch $sPosition
		Case "left"
			For $i = $iClient_Left To $iClient_Right
				$cCurrent_Color_From_Left = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
				If $cCurrent_Color_From_Left <> "000000" And $cCurrent_Color_From_Left <> "FFFFFF" And $cCurrent_Color_From_Left <> "FF0000" And $cCurrent_Color_From_Left <> "0000FF" And $i <> $iClient_Left Then
					Global $iGameArea_Left = $i
					ExitLoop
				EndIf
			Next

		Case "right"
			$i = $iClient_Right - 1

			While $i > $iClient_Left
				$cCurrent_Color_From_Right = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
				If $cCurrent_Color_From_Right <> "000000" And $cCurrent_Color_From_Right <> "FFFFFF" And $cCurrent_Color_From_Right <> "FF0000" And $cCurrent_Color_From_Right <> "0000FF" And $i <> $iClient_Right Then
					Global $iGameArea_Right = $i
					ExitLoop
				EndIf
				$i -= 1
			WEnd

		Case "top"
			For $i = $iClient_Top To $iClient_Bottom
				$cCurrent_Color_From_Top = Hex(FFGetPixel($iGameArea_Left, $i), 6)
				If $cCurrent_Color_From_Top <> "000000" And $cCurrent_Color_From_Top <> "FFFFFF" And $cCurrent_Color_From_Top <> "FF0000" And $cCurrent_Color_From_Top <> "0000FF" And $i <> $iClient_Top Then
					Global $iGameArea_Top = $i
					ExitLoop
				EndIf
			Next

		Case "bottom"
			$i = $iClient_Bottom ;; On initialise i avec la position Y du bas de la fenêtre

			While $i > $iClient_Top ;; Tant que i est supérieur à la position Y du haut de la fenêtre (pour éviter qu'on aille trop loin s'il ne trouve pas)
				$cCurrent_Color_From_Bottom = Hex(FFGetPixel($iGameArea_Left, $i), 6)
				;; On ne récupère ni le noir, ni le blanc, ni le bleu pur (utilisé par le debug) ni le rouge pur (utilisé par le debug aussi)
				If $cCurrent_Color_From_Bottom <> "000000" And $cCurrent_Color_From_Bottom <> "FFFFFF" And $cCurrent_Color_From_Bottom <> "FF0000" And $cCurrent_Color_From_Bottom <> "0000FF" And $i <> $iClient_Bottom Then
					Global $iGameArea_Bottom = $i
					ExitLoop
				EndIf
				$i -= 1
			WEnd

		Case Else
			Debug("Function GetPosition : Parameter not correct")
	EndSwitch
EndFunc

Bien, terminons notre fonction GetGameAreaMeasures(). Nous n'avons pour l'instant appelé que GetPosition("left"). Mais appelons les 3 autres, puis modifions l'appel à la fonction DrawLines() pour qu'elle nous dessine un joli carré bleu au format de l'aire de jeu ;).


GetPosition("left")
	GetPosition("right")
	GetPosition("top")
	GetPosition("bottom")

	DrawLines($iGameArea_Left, $iGameArea_Top, $iGameArea_Right, $iGameArea_Bottom, "zone", 0xFF0000)

C'est bien joli tout ça, mais nous devons maintenant enregistrer les dimensions de l'aire de jeu ! Pour, par la suite, avoir un système de pourcentage, etc...

Global $iGameArea_Width  = $iGameArea_Right  - $iGameArea_Left ;; Droite - gauche nous donne la largeur de l'aire de jeu
Global $iGameArea_Height = $iGameArea_Bottom - $iGameArea_Top  ;; Bas    - haut   nous donne la hauteur de l'aire de jeu

Voici ce que vous devriez avoir dans votre fichier ClientDetection.au3 à ce moment :

Cliquez pour révéler Cliquez pour masquer


#include <WinAPI.au3>
#include <WindowsConstants.au3>

#include "FastFind.au3"

Global $bDebug         = True, _
	   $bDebug_Console = True, _
	   $bDebug_Tray    = True, _
	   $bDebug_Lines   = True

Global  $sTitle, _
		$hHwnd_Active, _
		$sClass

HotKeySet("{ESC}", "Quit")
HotKeySet("{F2}", "SetWnd")
HotKeySet("{F3}", "GetClientMeasures")
HotKeySet("{F4}", "GetGameAreaMeasures")

While 1
	Sleep(250)
WEnd

Func GetGameAreaMeasures()
	FFSnapshot(0, 0, 0, 0, 1)

	GetPosition("left")
	GetPosition("right")
	GetPosition("top")
	GetPosition("bottom")

	DrawLines($iGameArea_Left, $iGameArea_Top, $iGameArea_Right, $iGameArea_Bottom, "zone", 0xFF0000)

	Global $iGameArea_Width  = $iGameArea_Right  - $iGameArea_Left ;; Droite - gauche nous donne la largeur de l'aire de jeu
	Global $iGameArea_Height = $iGameArea_Bottom - $iGameArea_Top  ;; Bas    - haut   nous donne la hauteur de l'aire de jeu
EndFunc

Func GetPosition($sPosition)
	Switch $sPosition
		Case "left"
			For $i = $iClient_Left To $iClient_Right
				$cCurrent_Color_From_Left = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
				If $cCurrent_Color_From_Left <> "000000" And $cCurrent_Color_From_Left <> "FFFFFF" And $cCurrent_Color_From_Left <> "FF0000" And $cCurrent_Color_From_Left <> "0000FF" And $i <> $iClient_Left Then
					Global $iGameArea_Left = $i
					ExitLoop
				EndIf
			Next

		Case "right"
			$i = $iClient_Right - 1

			While $i > $iClient_Left
				$cCurrent_Color_From_Right = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
				If $cCurrent_Color_From_Right <> "000000" And $cCurrent_Color_From_Right <> "FFFFFF" And $cCurrent_Color_From_Right <> "FF0000" And $cCurrent_Color_From_Right <> "0000FF" And $i <> $iClient_Right Then
					Global $iGameArea_Right = $i
					ExitLoop
				EndIf
				$i -= 1
			WEnd

		Case "top"
			For $i = $iClient_Top To $iClient_Bottom
				$cCurrent_Color_From_Top = Hex(FFGetPixel($iGameArea_Left, $i), 6)
				If $cCurrent_Color_From_Top <> "000000" And $cCurrent_Color_From_Top <> "FFFFFF" And $cCurrent_Color_From_Top <> "FF0000" And $cCurrent_Color_From_Top <> "0000FF" And $i <> $iClient_Top Then
					Global $iGameArea_Top = $i
					ExitLoop
				EndIf
			Next

		Case "bottom"
			$i = $iClient_Bottom ;; On initialise i avec la position Y du bas de la fenêtre

			While $i > $iClient_Top ;; Tant que i est supérieur à la position Y du haut de la fenêtre (pour éviter qu'on aille trop loin s'il ne trouve pas)
				$cCurrent_Color_From_Bottom = Hex(FFGetPixel($iGameArea_Left, $i), 6)
				;; On ne récupère ni le noir, ni le blanc, ni le bleu pur (utilisé par le debug) ni le rouge pur (utilisé par le debug aussi)
				If $cCurrent_Color_From_Bottom <> "000000" And $cCurrent_Color_From_Bottom <> "FFFFFF" And $cCurrent_Color_From_Bottom <> "FF0000" And $cCurrent_Color_From_Bottom <> "0000FF" And $i <> $iClient_Bottom Then
					Global $iGameArea_Bottom = $i
					ExitLoop
				EndIf
				$i -= 1
			WEnd

		Case Else
			Debug("Function GetPosition : Parameter not correct")
	EndSwitch
EndFunc

Func GetClientMeasures()
	$aMeasures = WinGetClientSize($sTitle)
	$aClient_Pos = WinGetPos($sTitle)

	Global $iClient_Width  = $aMeasures[0]
	Global $iClient_Height = $aMeasures[1]

	$iBorderSize_Y 	  = _WinAPI_GetSystemMetrics($SM_CYEDGE) + 2
	$iBorderSize_X 	  = _WinAPI_GetSystemMetrics($SM_CXEDGE) + 2
	$iHeight_TitleBar = _WinAPI_GetSystemMetrics($SM_CYCAPTION) + $iBorderSize_Y

	Global $iClient_Left = $aClient_Pos[0] + $iBorderSize_X
	Global $iClient_Right = $iClient_Left + $iClient_Width

	Global $iClient_Top = $aClient_Pos[1] + $iHeight_TitleBar
	Global $iClient_Bottom = $iClient_Top + $iClient_Height

	DrawLines($iClient_Left, $iClient_Top, $iClient_Right, $iClient_Bottom, "zone", 0x0000FF)

	Return 1
EndFunc

Func SetWnd()
	$hHwnd_Active = WinGetHandle("[ACTIVE]")
	$sTitle = WinGetTitle($hHwnd_Active)
	$sClass = GetClassName($hHwnd_Active)

	Debug("Handle    => " & $hHwnd_Active & @CRLF & _
		  "Title     => " & $sTitle & @CRLF & _
		  "ClassName => " & $sClass)

	Switch $sClass
		Case "ApolloRuntimeContentWindow"
			Switch $sTitle
				Case "Dofus"
					SetError(1)
					Return $sTitle
				Case Else
					Return $hHwnd_Active
			EndSwitch
		Case Else
			SetError(2)
			Return $sClass
	EndSwitch
EndFunc

Func GetClassName($hWnd)
	Local $aResult, $Length, $stText, $Text
	$Length = 4096
	$stText = DllStructCreate ("char[" & $Length & "]")
	$aResult = DllCall("User32.dll", "int", "GetClassName", "hwnd", $hWnd, "ptr", DllStructGetPtr($stText), "int", $Length)
	$Text = DllStructGetData($stText,1)
	$stText = 0
	Return $Text
EndFunc

Func DrawLines($iXS, $iYS, $iXE, $iYE, $sWhat = "line", $cColor = 0x000000)
	Switch $bDebug
		Case True
			Switch $bDebug_Lines
				Case True
					Global $hDC      = _WinAPI_GetWindowDC($sTitle) 			;; On récupère le handle du context
					Global $hPen     = _WinAPI_CreatePen($PS_SOLID, 2, $cColor) ;; On crée notre Pen avec la couleur passée en paramètre
					Global $obj_orig = _WinAPI_SelectObject($hDC, $hPen) 		;; On assemble le tout

					Switch $sWhat
						Case "line"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE)
						Case "zone"
							DrawLines($iXS, $iYS, $iXE, $iYE, "quad", $cColor)
							DrawLines($iXS, $iYS, $iXE, $iYE, "diagonale", $cColor)
						Case "diagonale"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE) ;; De haut à gauche jusque bas  à droite
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXS, $iYE) ;; De bas  à droite jusque haut à gauche
						Case "quad"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYS) ;; De haut à gauche jusque haut à droite   ---
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXE, $iYE) ;; De haut à droite jusque bas  à droite      |
							_WinAPI_DrawLine($hDC, $iXE, $iYE, $iXS, $iYE) ;; De bas  à droite jusque bas  à gauche   ___
							_WinAPI_DrawLine($hDC, $iXS, $iYE, $iXS, $iYS) ;; De bas  à gauche jusque haut à gauche  |
						Case "else"
							Debug("La forme que vous essayez de créer n'existe pas")
					EndSwitch
				Case False
					Debug("Le debug Lines n'est pas activé")
			EndSwitch
		Case False
			Debug("Le debug n'est pas activé")
	EndSwitch
EndFunc

Func Debug($sMessage)
	Switch $bDebug
		Case True
			Switch $bDebug_Console
				Case True
					ConsoleWrite("->=======================================================================" & @LF)
					ConsoleWrite($sMessage & @LF)
					ConsoleWrite("->=======================================================================" & @LF & @LF)
			EndSwitch

			Switch $bDebug_Tray
				Case True
					TrayTip("DEBUG", $sMessage, 2)
			EndSwitch
	EndSwitch
EndFunc

Func Quit()
	Debug("ESCAPE key pressed : Exiting")
	Sleep(1500)
	Exit
EndFunc

Et bien voilà, cette partie est terminée ! Prochaine étape : initialiser les cases ! :). A bientôt ! :ugeek:

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

Avant de continuer, j'ai ajouter les variables globales qui étaient dans les fonctions à l'extérieur des fonctions, tout en haut du fichier.

Ca nous épargnera des Warning d'AutoIt :).

Voici le fichier ainsi modifié :

Cliquez pour révéler Cliquez pour masquer


#include <WinAPI.au3>
#include <WindowsConstants.au3>

#include "FastFind.au3"

Global $bDebug         = True, _
	   $bDebug_Console = True, _
	   $bDebug_Tray    = True, _
	   $bDebug_Lines   = True

Global  $sTitle, _
		$hHwnd_Active, _
		$sClass

Global  $iGameArea_Left, _
		$iGameArea_Top, _
		$iGameArea_Right, _
		$iGameArea_Bottom

Global  $iClient_Left, _
		$iClient_Right, _
		$iClient_Top, _
		$iClient_Bottom

HotKeySet("{ESC}", "Quit")
HotKeySet("{F2}", "SetWnd")
HotKeySet("{F3}", "GetClientMeasures")
HotKeySet("{F4}", "GetGameAreaMeasures")

While 1
	Sleep(250)
WEnd

Func GetGameAreaMeasures()
	FFSnapshot(0, 0, 0, 0, 1)

	GetPosition("left")
	GetPosition("right")
	GetPosition("top")
	GetPosition("bottom")

	DrawLines($iGameArea_Left, $iGameArea_Top, $iGameArea_Right, $iGameArea_Bottom, "zone", 0xFF0000)

	Global $iGameArea_Width  = $iGameArea_Right  - $iGameArea_Left ;; Droite - gauche nous donne la largeur de l'aire de jeu
	Global $iGameArea_Height = $iGameArea_Bottom - $iGameArea_Top  ;; Bas    - haut   nous donne la hauteur de l'aire de jeu
EndFunc

Func GetPosition($sPosition)
	Switch $sPosition
	Case "left"
		For $i = $iClient_Left To $iClient_Right
			$cCurrent_Color_From_Left = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
			If $cCurrent_Color_From_Left <> "000000" And $cCurrent_Color_From_Left <> "FFFFFF" And $cCurrent_Color_From_Left <> "FF0000" And $cCurrent_Color_From_Left <> "0000FF" And $i <> $iClient_Left Then
				Global $iGameArea_Left = $i
				ExitLoop
			EndIf
		Next

	Case "right"
		$i = $iClient_Right - 1

		While $i > $iClient_Left
			$cCurrent_Color_From_Right = Hex(FFGetPixel($i, $iClient_Top + 20), 6)
			If $cCurrent_Color_From_Right <> "000000" And $cCurrent_Color_From_Right <> "FFFFFF" And $cCurrent_Color_From_Right <> "FF0000" And $cCurrent_Color_From_Right <> "0000FF" And $i <> $iClient_Right Then
				Global $iGameArea_Right = $i
				ExitLoop
			EndIf
			$i -= 1
		WEnd

	Case "top"
		For $i = $iClient_Top To $iClient_Bottom
			$cCurrent_Color_From_Top = Hex(FFGetPixel($iGameArea_Left, $i), 6)
			If $cCurrent_Color_From_Top <> "000000" And $cCurrent_Color_From_Top <> "FFFFFF" And $cCurrent_Color_From_Top <> "FF0000" And $cCurrent_Color_From_Top <> "0000FF" And $i <> $iClient_Top Then
				Global $iGameArea_Top = $i
				ExitLoop
			EndIf
		Next

	Case "bottom"
		$i = $iClient_Bottom ;; On initialise i avec la position Y du bas de la fenêtre

		While $i > $iClient_Top ;; Tant que i est supérieur à la position Y du haut de la fenêtre (pour éviter qu'on aille trop loin s'il ne trouve pas)
			$cCurrent_Color_From_Bottom = Hex(FFGetPixel($iGameArea_Left, $i), 6)
			;; On ne récupère ni le noir, ni le blanc, ni le bleu pur (utilisé par le debug) ni le rouge pur (utilisé par le debug aussi)
			If $cCurrent_Color_From_Bottom <> "000000" And $cCurrent_Color_From_Bottom <> "FFFFFF" And $cCurrent_Color_From_Bottom <> "FF0000" And $cCurrent_Color_From_Bottom <> "0000FF" And $i <> $iClient_Bottom Then
				Global $iGameArea_Bottom = $i
				ExitLoop
			EndIf
			$i -= 1
		WEnd

	Case Else
		Debug("Function GetPosition : Parameter not correct")
	EndSwitch

EndFunc

Func GetClientMeasures()
	$aMeasures = WinGetClientSize($sTitle)
	$aClient_Pos = WinGetPos($sTitle)

	Global $iClient_Width  = $aMeasures[0]
	Global $iClient_Height = $aMeasures[1]

	$iBorderSize_Y 	  = _WinAPI_GetSystemMetrics($SM_CYEDGE) + 2
	$iBorderSize_X 	  = _WinAPI_GetSystemMetrics($SM_CXEDGE) + 2
	$iHeight_TitleBar = _WinAPI_GetSystemMetrics($SM_CYCAPTION) + $iBorderSize_Y

	Global $iClient_Left = $aClient_Pos[0] + $iBorderSize_X
	Global $iClient_Right = $iClient_Left + $iClient_Width

	Global $iClient_Top = $aClient_Pos[1] + $iHeight_TitleBar
	Global $iClient_Bottom = $iClient_Top + $iClient_Height

	DrawLines($iClient_Left, $iClient_Top, $iClient_Right, $iClient_Bottom, "zone", 0x0000FF)

	Return 1
EndFunc

Func SetWnd()
	$hHwnd_Active = WinGetHandle("[ACTIVE]")
	$sTitle = WinGetTitle($hHwnd_Active)
	$sClass = GetClassName($hHwnd_Active)

	Debug("Handle    => " & $hHwnd_Active & @CRLF & _
		  "Title     => " & $sTitle & @CRLF & _
		  "ClassName => " & $sClass)

	Switch $sClass
		Case "ApolloRuntimeContentWindow"
			Switch $sTitle
				Case "Dofus"
					SetError(1)
					Return $sTitle
				Case Else
					Return $hHwnd_Active
			EndSwitch
		Case Else
			SetError(2)
			Return $sClass
	EndSwitch
EndFunc

Func GetClassName($hWnd)
	Local $aResult, $Length, $stText, $Text
	$Length = 4096
	$stText = DllStructCreate ("char[" & $Length & "]")
	$aResult = DllCall("User32.dll", "int", "GetClassName", "hwnd", $hWnd, "ptr", DllStructGetPtr($stText), "int", $Length)
	$Text = DllStructGetData($stText,1)
	$stText = 0
	Return $Text
EndFunc

Func DrawLines($iXS, $iYS, $iXE, $iYE, $sWhat = "line", $cColor = 0x000000)
	Switch $bDebug
		Case True
			Switch $bDebug_Lines
				Case True
					Global $hDC      = _WinAPI_GetWindowDC($sTitle) 			;; On récupère le handle du context
					Global $hPen     = _WinAPI_CreatePen($PS_SOLID, 2, $cColor) ;; On crée notre Pen avec la couleur passée en paramètre
					Global $obj_orig = _WinAPI_SelectObject($hDC, $hPen) 		;; On assemble le tout

					Switch $sWhat
						Case "line"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE)
						Case "zone"
							DrawLines($iXS, $iYS, $iXE, $iYE, "quad", $cColor)
							DrawLines($iXS, $iYS, $iXE, $iYE, "diagonale", $cColor)
						Case "diagonale"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYE) ;; De haut à gauche jusque bas  à droite
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXS, $iYE) ;; De bas  à droite jusque haut à gauche
						Case "quad"
							_WinAPI_DrawLine($hDC, $iXS, $iYS, $iXE, $iYS) ;; De haut à gauche jusque haut à droite   ---
							_WinAPI_DrawLine($hDC, $iXE, $iYS, $iXE, $iYE) ;; De haut à droite jusque bas  à droite      |
							_WinAPI_DrawLine($hDC, $iXE, $iYE, $iXS, $iYE) ;; De bas  à droite jusque bas  à gauche   ___
							_WinAPI_DrawLine($hDC, $iXS, $iYE, $iXS, $iYS) ;; De bas  à gauche jusque haut à gauche  |
						Case "else"
							Debug("La forme que vous essayez de créer n'existe pas")
					EndSwitch
				Case False
					Debug("Le debug Lines n'est pas activé")
			EndSwitch
		Case False
			Debug("Le debug n'est pas activé")
	EndSwitch
EndFunc

Func Debug($sMessage)
	Switch $bDebug
		Case True
			Switch $bDebug_Console
				Case True
					ConsoleWrite("->=======================================================================" & @LF)
					ConsoleWrite($sMessage & @LF)
					ConsoleWrite("->=======================================================================" & @LF & @LF)
			EndSwitch

			Switch $bDebug_Tray
				Case True
					TrayTip("DEBUG", $sMessage, 2)
			EndSwitch
	EndSwitch
EndFunc

Func Quit()
	Debug("ESCAPE key pressed : Exiting")
	Sleep(1500)
	Exit
EndFunc

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

[tab]3/- INITIALISATION DES CASES[/tab]

[tab]:?: Gné ? Tu veux dire quoi par initialiser les cases ? :oops:[/tab]

C'est très simple. Une zone de Dofus est décomposée en plusieurs cases. D'après des programmeurs socket il y en a 559, moi j'en ai toujours eu 600 (voire plus, ça dépend lesquelles je compte.

Petit exemple du résultat :

[thumb=239,500]http://i45.tinypic.com/2jg3wig.jpg[/thumb]

Bien sûr c'est ici affiché sous forme de mini-fenêtres, mais c'est surtout enregistré en variables globales. Nous allons voir ça.

Créons tout de suite notre fonction InitializeCases() dans le fichier portant le même nom.

[tab][/tab][tab][/tab]3a - Quelques petits calculs

La première chose à faire est bien sûr de calculer la hauteur d'une case, et sa largeur :

[Image Introuvable] Loading Image

Mais la calculer automatiquement en fonction de la taille de la zone de jeu, ça c'est une autre histoire :lol:

Pour se faire, j'ai pris comme base 100% la taille de zone de jeu de mon écran lorsque la fenêtre est maximisée.

Prenez la même, à moins que vous n'ayez pas de résolution 16/9 :

Func InitializeCases()
	$iGameArea_Width_100  = 1292
	$iGameArea_Height_100 = 1034

	$iCase_Width_100  = 88
	$iCase_Height_100 = 22
EndFunc

Où ces valeurs sont vraies pour ma résolution au maximum.

Ensuite, nous voulons savoir combien il y a de cases en X et en Y. Je vous épargne le calcul, j'en ai compté X=15 et Y=40.

Donc :

	$iNbCases_Width  = 15
	$iNbCases_Height = 40

Nous avons maintenant toutes les valeurs nécessaires à l'élaboration du pourcentage, puis du calcul Width*Height d'une case.

Je vous donne le code, c'est pas compliqué, ce n'est que des maths :

	$iPercent_Width  = Round($iGameArea_Width  * 100 / $iGameArea_Width_100,  2)
	$iPercent_Height = Round($iGameArea_Height * 100 / $iGameArea_Height_100, 2)

	$iCase_Width  = $iCase_Width_100  * $iPercent_Width  / 100
	$iCase_Height = $iCase_Height_100 * $iPercent_Height / 100

Pour ceux qui seraient un peu perdus, voici l'état du fichier InitializeCases.au3 à ce stade :

Cliquez pour révéler Cliquez pour masquer

Func InitializeCases()
	$iGameArea_Width_100  = 1292
	$iGameArea_Height_100 = 1034

	$iCase_Width_100  = 88
	$iCase_Height_100 = 22

	$iNbCases_Width  = 15
	$iNbCases_Height = 40

	$iPercent_Width  = Round($iGameArea_Width  * 100 / $iGameArea_Width_100,  2)
	$iPercent_Height = Round($iGameArea_Height * 100 / $iGameArea_Height_100, 2)

	$iCase_Width  = $iCase_Width_100  * $iPercent_Width  / 100
	$iCase_Height = $iCase_Height_100 * $iPercent_Height / 100
EndFunc

[tab][/tab][tab][/tab]3b - Initialisation de quelques variables

Dans cette partie, nous allons créer nos variables importantes.

Commencez par déclarer un Array $aCases en Global :

Global $aCases[1][4]

[tab]:?: Pourquoi [1][4] ?[/tab]

Une fois encore pas difficile, [1] pour qu'il ne soit pas vide, [4] parce que nous y stockerons :

0 -> Xpx
1 -> Ypx
2 -> Décalé ?
3 -> Cases à proximité

Où "Décalé ?" nous renseignera si la case est décalée vers la droite par rapport aux autres.

Exemple en images :

[Image Introuvable] Loading Image

Après ça, redimensionnons $aCases pour qu'il soit de la même taille que le nombre de cases (le + 1 vous allez le comprendre juste après) :

ReDim $aCases[$iNbCases_Height * $iNbCases_Width + 1][4]

Et tant qu'à faire, assignons-lui les premières cases pour que nous nous souvenions ce qu'il contient, et aussi pour que par la suite, nous appellerons $aCases[25] pour la case 25, et non $aCases[24]. Parce que comme vous le savez tous, les Array commencent à 0 et non à 1

	$aCases[0][0] = $iNbCases_Width
	$aCases[0][1] = $iNbCases_Height
	$aCases[0][2] = "Décalé?"
	$aCases[0][3] = "Proximité"

Finalement, déclarons 4 nouvelles variables globales :

	Global  $aCases_Left[20], _
			$aCases_Right[20], _
			$aCases_Top[15], _
			$aCases_Bottom[15]

Ce sont les cases situées aux extrêmes gauche/droite/haut/bas de l'aire de jeu.

Voilà, c'est terminé pour cette sous-partie.

L'état du fichier InitializeCases.au3 à ce stade :

Cliquez pour révéler Cliquez pour masquer

Func InitializeCases()
	Global $aCases[1][4]

	Global  $aCases_Left[20], _
			$aCases_Right[20], _
			$aCases_Top[15], _
			$aCases_Bottom[15]

	$iGameArea_Width_100  = 1292
	$iGameArea_Height_100 = 1034

	$iCase_Width_100  = 88
	$iCase_Height_100 = 22

	$iNbCases_Width  = 15
	$iNbCases_Height = 40

	$iPercent_Width  = Round($iGameArea_Width  * 100 / $iGameArea_Width_100,  2)
	$iPercent_Height = Round($iGameArea_Height * 100 / $iGameArea_Height_100, 2)

	$iCase_Width  = $iCase_Width_100  * $iPercent_Width  / 100
	$iCase_Height = $iCase_Height_100 * $iPercent_Height / 100

	ReDim $aCases[$iNbCases_Height * $iNbCases_Width + 1][4]

	$aCases[0][0] = $iNbCases_Width
	$aCases[0][1] = $iNbCases_Height
	$aCases[0][2] = "Décalé?"
	$aCases[0][3] = "Proximité"

EndFunc

A suivre !

RedBust

Re: [BIG Tuto] Détection du client + Initialisation des case

Bien foutu, les codes sont clairs.

Rien à redire, joli travail pour l'instant.

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

Super, ça fait plaisir un petit mot d'encouragement :).

4R7Y

Re: [BIG Tuto] Détection du client + Initialisation des case

Joli tuto :) bon courage pour la suite !

C'est très simple. Une zone de D. est décomposée en plusieurs cases. D'après des programmeurs socket il y en a 559, moi j'en ai toujours eu 600 (voire plus, ça dépend lesquelles je compte.

A mon avis le nombre est fixe :p

Anonymous

Re: [BIG Tuto] Détection du client + Initialisation des case

Exactement 560 cellules dont les numéros vont de 0 à 559.

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

Vous voyez pourtant, d'après mon screen, il y en a 600... Il faut juste savoir lesquelles il ne faut pas compter, en fait. Et puisqu'il y a un écart de 40 cases entre ce que vous dite et ce que j'ai, et que moi j'ai compté 15W * 40H, à mon avis j'ai compté une colonne qu'il ne fallait pas =D.

Joli tuto bon courage pour la suite !

Merci à toi =D

Anonymous

Re: [BIG Tuto] Détection du client + Initialisation des case

Bonjour, je ne code pas en Autoit mais c'est du très bon travail merci à toi ;)

Geraff

Re: [BIG Tuto] Détection du client + Initialisation des case

Le faire sur plusieurs posts est contraignant pour la visionneuse, je vais voir soit pour le regrouper en un seul post ou le scinder en posts bien distincts avec numéro de parties.

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

La... Visionneuse? J'ai voulu mettre sur plusieurs posts pour créer un lien qui amène sur chaque partie. Donc tu penses qu'il faudrait mettre la partie 1 sur un post, la partie 1a sur un autre, 1b sur encore un autre, etc?

Geraff

Re: [BIG Tuto] Détection du client + Initialisation des case

Oui le scinder complètement en plusieurs tuto.

Sinon il faut que je prévoie ça pour la visionneuse en faisant un cas particulier dans la bdd avec le nombre de posts mais c'est chiant.

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

Je ne sais même pas ce qu'est la visionneuse ! :D. Et donc le problème, c'est que mon tuto est... Trop grand? C'est moche, quand même. Surtout en sachant qu'il n'est pas encore terminé. Heureusement que ce n'est pas un tuto complet sur comment créé un bot >.<.

Geraff

Re: [BIG Tuto] Détection du client + Initialisation des case

https://cadernis.com/d/1224

d4rkv4n

Re: [BIG Tuto] Détection du client + Initialisation des case

D'accord. Dans ce cas, je devrais, plutôt que de faire ça en plusieurs posts, le faire en plusieurs topics. La visionneuse devrait ainsi bien le prendre en compte.