Ce site est optimisé pour être consulté depuis un navigateur moderne dans lequel JavaScript est activé.

PixelBot: how to manage Dofus Mouse Cursors

KekaBron

One of the most typical problems when someone wants to create a pixelbot for Dofus is how to detect if a resource is collectable/farmeable, or not. The approach we'll use today is to track the mouse cursor, which changes depending on the resource status.

Just a quick reminder, if the resource is collectable, the mouse cursor can be like this:

Whereas if its not, we can have something like this:

So, how can we differentiate between them? I first tried to take a screenshot of the mouse cursor, but guess what, Windows screenshots dont capture the mouse cursor... also I could have tried to locate the cursor images on the game directory but I was lazy :(

AutoHotKey also has native functions that can tell you what mouse cursor are you using, but sadly for custom cursors from games etc it returns "unknown".

Then I found this post on the AutoHotKey forum and that solved all :D

Just run the script and capture the custom cursors you need using

CaptureCursor()

It will be saved like this:

Then use

IsMatchCursor()

function to compare the real time cursor with the image you saved.

Video Demo (make sure to watch it on 1080p otherwise it will be blurry):

[MEDIA=dailymotion]x84qbfy[/MEDIA]

Script Example for AutoHotKey (first capture a cursor with F11, then use F12 to compare):

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
#SingleInstance Force ; Allow only one running instance of script.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.



SetTitleMatchMode RegEx
IfWinExist, .*Dofus.*
{
WinActivate
Sleep, 1500
WinMaximize
Sleep, 1000
CoordMode, Pixel, Screen
CoordMode, Mouse, Screen


;capturing current mouse cursor and save to "testCursor.bmp"
F11::
    CaptureCursor("testCursor.bmp")
return

;compare to testCursor.bmp and current mouse cursor
F12::
    loop
    {
        id := IsMatchCursor("testCursor.bmp")? "IT CAN BE FARMED :D" : "RESOURCE WASTED :("
        ToolTip % id
        Sleep, 100
    }
return

;---------------------------------------------------------------
;    CaptureCursor and IsMatchCursor
;---------------------------------------------------------------
;captureTo: "clipboard"=save to clipboard , "bitmap_handle"=return current cursor bitmap handle.
;return: 0=fail , 1=success
CaptureCursor(captureTo="clipboard", cursorSize=32)
{
    VarSetCapacity(CURSORINFO, A_PtrSize=8? 24:20, 0)
    VarSetCapacity(ICONINFO, A_PtrSize=8? 32:20, 0)
    NumPut(A_PtrSize=8? 24:20, CURSORINFO, 0,"UInt")
    DllCall("GetCursorInfo", "UPTR", &CURSORINFO)
    hCursor := NumGet(CURSORINFO, 8, "UPtr")
    flags := NumGet(CURSORINFO, 4, "UInt")
    if !hCursor or !flags
        return 0
    hCursor := DllCall("CopyIcon", "UPTR", hCursor)
    DllCall("GetIconInfo", "UPTR", hCursor, "UPTR", &ICONINFO)

    mDC := DllCall("CreateCompatibleDC", "UPTR", 0, "UPTR")
    hBM := CreateDIBSection(mDC, cursorSize, cursorSize)
    oBM := DllCall("SelectObject", "UPTR", mDC, "UPTR", hBM, "UPTR")
   
    DllCall("DrawIcon", "UPTR", mDC, "int",0, "int",0, "UPTR", hCursor)
   
    DllCall("SelectObject", "UPTR", mDC, "UPTR", oBM)
    DllCall("DeleteDC", "UPTR", mDC)
    DllCall("DestroyIcon", "UPTR", hCursor)
    If hbmMask := NumGet(ICONINFO, A_PtrSize=8? 16:12, "UPtr")
        DllCall("DeleteObject", "UPTR", hbmMask)
    If hbmColor := NumGet(ICONINFO, A_PtrSize=8? 24:16, "UPtr")
        DllCall("DeleteObject", "UPTR", hbmColor)

    if captureTo=bitmap_handle
        return hBM
    If captureTo=clipboard
        SetClipboardData(hBM)
    else
        SaveHBITMAPToFile(hBM, captureTo)
    DllCall("DeleteObject", "UPTR", hBM)
    return 1
}

;compare cursor bmp file to current mouse cursor.
; 1 : cursor image match
; 0 : cursor image unmatch
; ""; hide mouse cursor or can't get cursor handle.
IsMatchCursor(bmpCursorFile)
{
    if !hCursorBmp := CaptureCursor("bitmap_handle", bmpSize:=32)
        return ""
    hSourceBmp := LoadBMP(bmpCursorFile)
    return !CompareBitmap(hSourceBmp, hCursorBmp, bmpSize)
}


;---------------------------------------------------------------
;    Sub function
;---------------------------------------------------------------
;this function takes two bitmaps and compares the first 32x32 pixel square on them
;hBM1 and hBM2: bitmap handle
;return: 0=match, 1=unmatch
CompareBitmap(hBM1, hBM2, size=32)
{
    x=0
    mDC1 := DllCall("CreateCompatibleDC", "Uint", 0)            ;create DC compatible with screen
    mDC2 := DllCall("CreateCompatibleDC", "Uint", 0)
    oBM1 := DllCall("SelectObject", "UPTR", mDC1, "UPTR", hBM1)    ;put the object in the device context
    oBM2 := DllCall("SelectObject", "UPTR", mDC2, "UPTR", hBM2)
    while x < size
    {
        y=0
        while y < size
        {
            color1 := DllCall("GetPixel", "UPTR", mDC1, "int", x, "int",y)    ;get the RGB of pixel (x, y)
            color2 := DllCall("GetPixel", "UPTR", mDC2, "int", x, "int",y)
            if color1 <> %color2%    ;if colors are different, didn't match
                return 1
            y+=1
        }
        x+=1
    }
    DllCall("SelectObject", "UPTR", mDC1, "UPTR", oBM1)    ;put the original contents back in DC
    DllCall("SelectObject", "UPTR", mDC2, "UPTR", oBM2)
    DllCall("DeleteDC", "UPTR", mDC1)                    ;delete DC (prevent memory leak)
    DllCall("DeleteDC", "UPTR", mDC2)
    DllCall("DeleteObject", "UPTR", hBM1)                ;delete the images in memory
    DllCall("DeleteObject", "UPTR", hBM2)
    return 0    ;0 return if match
}

CreateDIBSection(hDC, nW, nH, bpp = 32, ByRef pBits = "")
{
    VarSetCapacity(BITMAPINFO, 44, 0)
    NumPut(44, BITMAPINFO, 0,"UInt")
    NumPut(nW, BITMAPINFO, 4,"Int")
    NumPut(nH, BITMAPINFO, 8,"Int")
    NumPut(1, BITMAPINFO, 12,"UShort")
    NumPut(bpp, BITMAPINFO, 14,"UShort")
    Return    DllCall("gdi32\CreateDIBSection", "UPTR", hDC, "UPTR", &BITMAPINFO, "Uint", 0, "UPTR", pBits, "Uint", 0, "Uint", 0)
}

SetClipboardData(hBitmap)
{
    VarSetCapacity(DIBSECTION, A_PtrSize=8? 104:84, 0)
    NumPut(40, DIBSECTION, A_PtrSize=8? 32:24,"UInt")    ;dsBmih.biSize
    DllCall("GetObject", "UPTR", hBitmap, "int", A_PtrSize=8? 104:84, "UPTR", &DIBSECTION)
    biSizeImage := NumGet(DIBSECTION, A_PtrSize=8? 52:44, "UInt")
    hDIB :=    DllCall("GlobalAlloc", "Uint", 2, "Uint", 40+biSizeImage)
    pDIB :=    DllCall("GlobalLock", "UPTR", hDIB)
    DllCall("RtlMoveMemory", "UPTR", pDIB, "UPTR", &DIBSECTION + (A_PtrSize=8? 32:24), "Uint", 40)
    DllCall("RtlMoveMemory", "UPTR", pDIB+40, "Uint", NumGet(DIBSECTION, A_PtrSize=8? 24:20, "UPtr"), "Uint", biSizeImage)
    DllCall("GlobalUnlock", "UPTR", hDIB)
    DllCall("DeleteObject", "UPTR", hBitmap)
    DllCall("OpenClipboard", "Uint", 0)
    DllCall("EmptyClipboard")
    DllCall("SetClipboardData", "Uint", 8, "UPTR", hDIB)
    DllCall("CloseClipboard")
}

LoadBMP(bmpFile)
{
    bmpFile := GetValidFilePath(bmpFile)
    hBmp := DllCall("LoadImage","Uint", 0, "str", bmpFile, "Uint", 0, "int", 32, "int",32, "Uint", 0x00000010) ;load the image from file
    return hBmp
}

SaveHBITMAPToFile(hBitmap, sFile)
{
    sFile := GetValidFilePath(sFile)
    VarSetCapacity(DIBSECTION, A_PtrSize=8? 104:84, 0)
    NumPut(40, DIBSECTION, A_PtrSize=8? 32:24,"UInt")    ;dsBmih.biSize
    DllCall("GetObject", "UPTR", hBitmap, "int", A_PtrSize=8? 104:84, "UPTR", &DIBSECTION)
    hFile:=    DllCall("CreateFile", "UPTR", &sFile, "Uint", 0x40000000, "Uint", 0, "Uint", 0, "Uint", 2, "Uint", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "int64P", 0x4D42|14+40+(biSizeImage:=NumGet(DIBSECTION, A_PtrSize=8? 52:44, "UInt"))<<16, "Uint", 6, "UintP", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "int64P", 54<<32, "Uint", 8, "UintP", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "UPTR", &DIBSECTION + (A_PtrSize=8? 32:24), "Uint", 40, "UintP", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "Uint", NumGet(DIBSECTION, A_PtrSize=8? 24:20, "UPtr"), "Uint", biSizeImage, "UintP", 0, "Uint", 0)
    DllCall("CloseHandle", "UPTR", hFile)
}

GetValidFilePath(filename)
{
    SplitPath, filename, , sDir, sExt, sName
    IfNotInString, sDir, :
        sDir = %A_ScriptDir%\%sDir%
    filename = %sDir%\%sName%.%sExt%
    StringReplace, filename, filename, \\, \, All
    return filename
}

;---------------------------------------------------------------
;    Struct List
;---------------------------------------------------------------
/*

typedef struct {
  DWORD   cbSize;
  DWORD   flags;
  HCURSOR hCursor;
  POINT   ptScreenPos;
} CURSORINFO, *PCURSORINFO, *LPCURSORINFO;

typedef struct _ICONINFO {
  BOOL    fIcon;
  DWORD   xHotspot;
  DWORD   yHotspot;
  HBITMAP hbmMask;
  HBITMAP hbmColor;
} ICONINFO, *PICONINFO;

typedef struct tagDIBSECTION {
  BITMAP           dsBm;
  BITMAPINFOHEADER dsBmih;
  DWORD            dsBitfields[3];
  HANDLE           dshSection;
  DWORD            dsOffset;
} DIBSECTION, *PDIBSECTION;

typedef struct tagBITMAPINFOHEADER {
  DWORD biSize;
  LONG  biWidth;
  LONG  biHeight;
  WORD  biPlanes;
  WORD  biBitCount;
  DWORD biCompression;
  DWORD biSizeImage;
  LONG  biXPelsPerMeter;
  LONG  biYPelsPerMeter;
  DWORD biClrUsed;
  DWORD biClrImportant;
} BITMAPINFOHEADER;

typedef struct tagBITMAP {
  LONG   bmType;
  LONG   bmWidth;
  LONG   bmHeight;
  LONG   bmWidthBytes;
  WORD   bmPlanes;
  WORD   bmBitsPixel;
  LPVOID bmBits;
} BITMAP, *PBITMAP;

typedef struct tagBITMAPINFO {
  BITMAPINFOHEADER bmiHeader;
  RGBQUAD          bmiColors[1];
} BITMAPINFO, *PBITMAPINFO;

typedef struct tagRGBQUAD {
  BYTE rgbBlue;
  BYTE rgbGreen;
  BYTE rgbRed;
  BYTE rgbReserved;
} RGBQUAD;

*/
}

sokalbr

Hi Keka,

Thanks for all your sharing !! I'm really interested by them bc I want to code a pixelbot with Autoit.

But i don't understand in wich case your suggestion is usefull ? Bc if you check pixel you can know if the ressource is collectable ?

AN other question. I see that you don't search pixel with a algo but just getpixel and check if the pixel belong to a collectable ressource (manually). I understand it and it work fine but, i rly want to made an search pixel algo.

So i think i have two option :

- Coding a script recorder to copy your idea (Get pixel color manually, on each map, press a key for recording). The problem is if the ressource is not collectable when you record :-)

- Coding a search algo. Did you have some idea for the best path to me ? Maybe Is it possible to search multiples pixel in a specific zone to validate the ressource ?

Well for the moment i just looking for idea :-)

Thanks again and have a nice day.

Soka.

KekaBron

Hey @sokalbr remember I'm using AutoHotKey, maybe on AutoIt there is better or fancier ways of doing what you tell. Anyways, using AutoHotKey I've tried pretty much every approach, from searching all over the screen for certain pixel colors (resources), search by areas, search by color pallets, manual search with pixel comparison and finally manual search with mouse cursor comparison. As I said on other posts, I think the manual approach is the most boring to code, but at the same time, the most efficient one considering execution time and computational cost. I would recommend you the mouse cursor approach, since it is the fastest and most accurate of any other,

But, since you really want to investigate, I will give you some hints about the issues you will face when trying the 2 approaches you want.

- Coding a script recorder to copy your idea (Get pixel color manually, on each map, press a key for recording). The problem is if the ressource is not collectable when you record

This is not bad. I had some problems when I used this method:

1- Each ressource is not only one color, on darker or lighter areas, it can vary. You will need a color pallet and make a regex. Also as you mentioned if the resource is not collectable you will have to wait to record its position! that sucks... I solved that by using my own private 2.53 server, there every resource is always up lmao :cool:

2. What are you going to do with fish? it's an absolute pain to record the colors of the fish on rivers and seas. Literally every area has different water color...

3. What if there is a mob of monsters in front of your resource? you wont be able to detect it. What if you force the click? you will get in combat and probably be killed if its a strong mob (abyss of sufokia for example xd). Tip: press Shift always, that way you wont start a combat when clicking on a mob.

- Coding a search algo. Did you have some idea for the best path to me ? Maybe Is it possible to search multiples pixel in a specific zone to validate the ressource ?

1- Ok I first tried to store an image of a resource, and the compare it against all the screen and try to find similar images. The problem is that is not accurate enough, it will only detect it like 50% of the times if you are lucky. As soon as the map is slightly different, it will not find it.

2-I also tried to search for a bunch of pixels, like the chestnut on chestnut trees. Same issues, sometimes it finds it, sometimes not. And it is slow.

3-You can try an algo that moves the mouse cursor all over the screen until it changes to the "collectable" cursor. But its slow.

4. You can leave autoit and try your luck with python or other languages that offer a big integration with advanced image search libraries, but yeah, it is time consuming and I doubt it will be more efficient than the manual search approach.

I will give you an example of one script that farms using the manual mouse cursor approach on frigost to farm this thing.

Some functions are in spanish but you can use a translator. Good luck little padawan :3

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
#SingleInstance Force ; Allow only one running instance of script.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

; Disclaimer: Este script ha sido creado por Keka Bron con un objetivo de mero aprendizaje y con interés educativo para los demás.
            ; En ningún caso autorizo el uso fraudulento de este script o cualquier otro script derivado para objetivos ligados a realizar trampas
            ; en el juego Dofus o cualquier otro. Keka Bron apoya el fair play y anima a todos a jugar de manera ética, así como a seguir las reglas de Dofus.
            ; 07/10/2021

SetTitleMatchMode RegEx
IfWinExist, .*Dofus.*
{
WinActivate 
Sleep, 1500
WinMaximize
Sleep, 1000
CoordMode, Pixel, Screen
CoordMode, Mouse, Screen

global times
CloseScript("alamotemblon2.ahk")

Loop{
Pods()
Sleep, 2000
AlamoTemblon()
}

AlamoTemblon(){
    Frigost()
    Move("arriba", 5)
    Move("derecha", 5)
    ;--------------------------------------
    ; [-73, -46]
    Farm(1288, 578, 5000)
    Move("arriba", 3)
    ;--------------------------------------
    ; [-73, -49]
    Farm(1376, 190, 5000)
    Move("izquierda", 2)
    ;--------------------------------------
    ; [-75, -49]
    Farm(1244, 385, 5000)
    Move("derecha", 1)
    Move("arriba", 3)
    ;--------------------------------------
    ; [-74, -52]
    Farm(1464, 450, 5000)
    Move("arriba", 2)
    ;--------------------------------------
    ; [-74, -54]
    Farm(1030, 707, 5000)
    Move("derecha", 1)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-73, -53]
    Farm(1291, 623, 5000)
    Move("derecha", 1)
    Move("arriba", 1)
    ;--------------------------------------
    ; [-72, -54]
    Farm(760, 280, 5000)
    Farm(1289, 277, 5000)
    Move("derecha", 6)
    Move("abajo", 6)
    ;--------------------------------------
    ; [-66, -48]
    Farm(499, 755, 5000)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-66, -47]
    Farm(822, 484, 5000)
    Move("derecha", 1)
    ;--------------------------------------
    ; [-65, -47]
    Farm(987, 298, 5000)
    Move("arriba", 2)
    Move("derecha", 1)
    ;--------------------------------------
    ; [-64, -49]
    Farm(1290, 234, 5000)
    Move("arriba", 2)
    Move("derecha", 1)
    Move("arriba", 2)
    Move("derecha", 3)
    ;--------------------------------------
    ; [-60, -53]
    Farm(1035, 587, 5000)
    Move("arriba", 1)
    Move("derecha", 2)
    ;--------------------------------------
    ; [-58, -54]
    Farm(804, 475, 5000)
    Move("izquierda", 1)
    Move("arriba", 2)
    Move("derecha", 2)
    ;--------------------------------------
    ; [-57, -56]
    Farm(468, 687, 5000)
    Move("arriba", 1)
    Move("derecha", 2)
    ;--------------------------------------
    ; [-55, -57]
    Farm(844, 232, 5000)
    Move("arriba", 2)
    Move("izquierda", 2)
    ;--------------------------------------
    ; [-57, -59]
    Farm(670, 623, 5000)
    Move("arriba", 2)
    Move("izquierda", 2)
    ;--------------------------------------
    ; [-57, -59]
    Farm(976, 559, 5000)
    Move("izquierda", 5)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-64, -60]
    Farm(1246, 558, 5000)
    Move("izquierda", 1)
    ;--------------------------------------
    ; [-65, -60]
    Farm(553, 515, 5000)
    Move("izquierda", 3)
    ;--------------------------------------
    ; [-68, -60]
    Farm(539, 648, 5000)
    Move("arriba", 1)
    Move("derecha", 3)
    Move("arriba", 2)
    ;--------------------------------------
    ; [-65, -63]
    Farm(596, 279, 5000)
    Move("derecha", 1)
    ;--------------------------------------
    ; [-64, -63]
    Farm(890, 340, 5000)
    Move("derecha", 3)
    Move("arriba", 1)
    ;--------------------------------------
    ; [-61, -64]
    Farm(1236, 302, 5000)
    Move("derecha", 3)
    ;--------------------------------------
    ; [-58, -64]
    Farm(1030, 538, 5000)
    Move("arriba", 4)
    ;--------------------------------------
    ; [-58, -68]
    Farm(1463, 278, 5000)
    Move("derecha", 2)
    ;--------------------------------------
    ; [-56, -68]
    Farm(1463, 362, 5000)
    Send {Shift up}
    Sleep, 10000
    ;--------------------------------------
    ;--------------------------------------
    ;--------------------------------------
    Sepultado()
    Move("izquierda", 1)
    Move("abajo", 3)
    Move("izquierda", 3)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-81, -69]
    Farm(890, 472, 5000)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-81, -68]
    Farm(1188, 286, 5000)
    Farm(1020, 537, 5000)
    Move("derecha", 1)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-80, -67]
    Farm(585, 407, 5000)
    Move("derecha", 1)
    Move("abajo", 1)
    ;--------------------------------------
    ; [-79, -66]
    Farm(899, 213, 5000)
    Farm(1333, 428, 5000)
    Move("derecha", 1)
    ;--------------------------------------
    ; [-78, -66]
    Farm(1203, 494, 5000)
    Farm(1149, 602, 5000)
    Send {Shift up}
    Sleep, 10000
    Pods()
}

Move(direction, repeat)
{
    times=0
    counter=0
    Send {Shift down}
    while(times<repeat)
    {
    Switch direction
        {
            case "derecha":
                MouseMove, 1650, 450
            case "izquierda":
                MouseMove, 324, 540
            case "arriba":
                MouseMove, 1000, 45
            case "abajo":
                MouseMove, 891, 902
        }
        Click
        times+=1
    Loop
    {
        PixelGetColor, color, 200, 200
        PixelGetColor, color2, 700, 350
        PixelGetColor, color3, 1650, 450
        counter+=1
        if(counter>500)
            {   
                RunWait, alamotemblon2.ahk, %A_ScriptDir%
            }
    } Until (color = 0x000000 and color2 = 0x000000 and color3 = 0x000000)
    Sleep, 2000
    }
    return
}


check(){
sleep, 500
if (checkFight() = 1)
    {
    Send {Shift up}
    Sleep, 1000
    RunWait, pelea.ahk, %A_ScriptDir%
    Sleep, 2000
    Send {Enter}
    Sleep, 5000
    CloseScript("pelea.ahk")
    RunWait, alamotemblon2.ahk, %A_ScriptDir%
    Sleep, 5000
    }
return
}

checkFight(){
PixelGetColor, color, 160, 488, RGB
PixelGetColor, color2, 1732, 476, RGB
PixelGetColor, color3, 1343, 960, RGB
if (color = 0x000000 and color2 = 0x000000 and color3 = 0xCEF000)
return 1
else
return 0
}

Pods()
{
    PixelGetColor, colorPods, 1300, 1018, RGB
    if (colorPods = 0x60BE35)
    {
        irABanco()
        Sleep, 1500
        RunWait, alamotemblon2.ahk, %A_ScriptDir%
    }
    else
    {
        return
    }
}

irABanco()
{
    Frigost()
    Move("derecha", 1)
    Interact(1095, 517, 7000) ;bank door
    Interact(975, 532, 2000) ;talk to the owl
    Interact(920, 749, 3000) ;open my bank account
    Interact(1477, 146, 3000) ;resources
    Interact(1262, 149, 1500) ;advanced transfer arrow
    Interact(1311, 180, 5000) ;transfer visible items
    Interact(1551, 108, 3000) ;close bank
    return
}

Farm(posX, posY, timer)
{
    Send {Shift down}
    MouseMove, %posX%, %posY%
    Sleep, 250
    id := IsMatchCursor("testCursor.bmp")
    Switch id
    {
        case 0:
            return
        case 1:
            Click
            Sleep, %timer%
            check()
            return
    }
    return
}

Interact(posX, posY, timer)
{
    MouseMove, %posX%, %posY%
    Click
    Sleep, %timer%
    return
}

Frigost()
{
    Send {h} ;Ir al merkasako
    Sleep, 3000
    Interact(562, 361, 2000)
    Interact(1107, 229, 500)
    Send burgo
    Sleep, 1000
    Send {Enter}
    Sleep, 5000   
    Send {Shift up}

}

Sepultado()
{
    Send {h} ;Ir al merkasako
    Sleep, 3000
    Interact(562, 361, 2000)
    Interact(1107, 229, 500)
    Send sepultado
    Sleep, 1000
    Send {Enter}
    Sleep, 5000   
    Send {Shift up}

}

CloseScript(Name)
    {
    DetectHiddenWindows On
    SetTitleMatchMode RegEx
    IfWinExist, i)%Name%.* ahk_class AutoHotkey
        {
        WinClose
        WinWaitClose, i)%Name%.* ahk_class AutoHotkey, , 2
        If ErrorLevel
            return
        else
            return
        }
    else
        return
    }
    

Esc:: ExitApp
+Esc:: ExitApp

;---------------------------------------------------------------
;    CaptureCursor and IsMatchCursor
;---------------------------------------------------------------
;captureTo: "clipboard"=save to clipboard , "bitmap_handle"=return current cursor bitmap handle.
;return: 0=fail , 1=success
CaptureCursor(captureTo="clipboard", cursorSize=32)
{
    VarSetCapacity(CURSORINFO, A_PtrSize=8? 24:20, 0)
    VarSetCapacity(ICONINFO, A_PtrSize=8? 32:20, 0)
    NumPut(A_PtrSize=8? 24:20, CURSORINFO, 0,"UInt")
    DllCall("GetCursorInfo", "UPTR", &CURSORINFO)
    hCursor := NumGet(CURSORINFO, 8, "UPtr")
    flags := NumGet(CURSORINFO, 4, "UInt")
    if !hCursor or !flags
        return 0
    hCursor := DllCall("CopyIcon", "UPTR", hCursor)
    DllCall("GetIconInfo", "UPTR", hCursor, "UPTR", &ICONINFO)

    mDC := DllCall("CreateCompatibleDC", "UPTR", 0, "UPTR")
    hBM := CreateDIBSection(mDC, cursorSize, cursorSize)
    oBM := DllCall("SelectObject", "UPTR", mDC, "UPTR", hBM, "UPTR")
    
    DllCall("DrawIcon", "UPTR", mDC, "int",0, "int",0, "UPTR", hCursor)
    
    DllCall("SelectObject", "UPTR", mDC, "UPTR", oBM)
    DllCall("DeleteDC", "UPTR", mDC)
    DllCall("DestroyIcon", "UPTR", hCursor)
    If hbmMask := NumGet(ICONINFO, A_PtrSize=8? 16:12, "UPtr")
        DllCall("DeleteObject", "UPTR", hbmMask)
    If hbmColor := NumGet(ICONINFO, A_PtrSize=8? 24:16, "UPtr")
        DllCall("DeleteObject", "UPTR", hbmColor)

    if captureTo=bitmap_handle
        return hBM
    If captureTo=clipboard
        SetClipboardData(hBM)
    else
        SaveHBITMAPToFile(hBM, captureTo)
    DllCall("DeleteObject", "UPTR", hBM)
    return 1
}


;compare cursor bmp file to current mouse cursor.
; 1 : cursor image match
; 0 : cursor image unmatch
; ""; hide mouse cursor or can't get cursor handle.
IsMatchCursor(bmpCursorFile)
{
    if !hCursorBmp := CaptureCursor("bitmap_handle", bmpSize:=32)
        return ""
    hSourceBmp := LoadBMP(bmpCursorFile)
    return !CompareBitmap(hSourceBmp, hCursorBmp, bmpSize)
}


;---------------------------------------------------------------
;    Sub function
;---------------------------------------------------------------
;this function takes two bitmaps and compares the first 32x32 pixel square on them
;hBM1 and hBM2: bitmap handle
;return: 0=match, 1=unmatch
CompareBitmap(hBM1, hBM2, size=32)
{
    x=0
    mDC1 := DllCall("CreateCompatibleDC", "Uint", 0)            ;create DC compatible with screen
    mDC2 := DllCall("CreateCompatibleDC", "Uint", 0)
    oBM1 := DllCall("SelectObject", "UPTR", mDC1, "UPTR", hBM1)    ;put the object in the device context
    oBM2 := DllCall("SelectObject", "UPTR", mDC2, "UPTR", hBM2)
    while x < size
    {
        y=0
        while y < size
        {
            color1 := DllCall("GetPixel", "UPTR", mDC1, "int", x, "int",y)    ;get the RGB of pixel (x, y)
            color2 := DllCall("GetPixel", "UPTR", mDC2, "int", x, "int",y)
            if color1 <> %color2%    ;if colors are different, didn't match
                return 1
            y+=1
        }
        x+=1
    }
    DllCall("SelectObject", "UPTR", mDC1, "UPTR", oBM1)    ;put the original contents back in DC
    DllCall("SelectObject", "UPTR", mDC2, "UPTR", oBM2)
    DllCall("DeleteDC", "UPTR", mDC1)                    ;delete DC (prevent memory leak)
    DllCall("DeleteDC", "UPTR", mDC2)
    DllCall("DeleteObject", "UPTR", hBM1)                ;delete the images in memory
    DllCall("DeleteObject", "UPTR", hBM2)
    return 0    ;0 return if match
}

CreateDIBSection(hDC, nW, nH, bpp = 32, ByRef pBits = "")
{
    VarSetCapacity(BITMAPINFO, 44, 0)
    NumPut(44, BITMAPINFO, 0,"UInt")
    NumPut(nW, BITMAPINFO, 4,"Int")
    NumPut(nH, BITMAPINFO, 8,"Int")
    NumPut(1, BITMAPINFO, 12,"UShort")
    NumPut(bpp, BITMAPINFO, 14,"UShort")
    Return    DllCall("gdi32\CreateDIBSection", "UPTR", hDC, "UPTR", &BITMAPINFO, "Uint", 0, "UPTR", pBits, "Uint", 0, "Uint", 0)
}

SetClipboardData(hBitmap)
{
    VarSetCapacity(DIBSECTION, A_PtrSize=8? 104:84, 0)
    NumPut(40, DIBSECTION, A_PtrSize=8? 32:24,"UInt")    ;dsBmih.biSize
    DllCall("GetObject", "UPTR", hBitmap, "int", A_PtrSize=8? 104:84, "UPTR", &DIBSECTION)
    biSizeImage := NumGet(DIBSECTION, A_PtrSize=8? 52:44, "UInt")
    hDIB :=    DllCall("GlobalAlloc", "Uint", 2, "Uint", 40+biSizeImage)
    pDIB :=    DllCall("GlobalLock", "UPTR", hDIB)
    DllCall("RtlMoveMemory", "UPTR", pDIB, "UPTR", &DIBSECTION + (A_PtrSize=8? 32:24), "Uint", 40)
    DllCall("RtlMoveMemory", "UPTR", pDIB+40, "Uint", NumGet(DIBSECTION, A_PtrSize=8? 24:20, "UPtr"), "Uint", biSizeImage)
    DllCall("GlobalUnlock", "UPTR", hDIB)
    DllCall("DeleteObject", "UPTR", hBitmap)
    DllCall("OpenClipboard", "Uint", 0)
    DllCall("EmptyClipboard")
    DllCall("SetClipboardData", "Uint", 8, "UPTR", hDIB)
    DllCall("CloseClipboard")
}

LoadBMP(bmpFile)
{
    bmpFile := GetValidFilePath(bmpFile)
    hBmp := DllCall("LoadImage","Uint", 0, "str", bmpFile, "Uint", 0, "int", 32, "int",32, "Uint", 0x00000010) ;load the image from file
    return hBmp
}

SaveHBITMAPToFile(hBitmap, sFile)
{
    sFile := GetValidFilePath(sFile)
    VarSetCapacity(DIBSECTION, A_PtrSize=8? 104:84, 0)
    NumPut(40, DIBSECTION, A_PtrSize=8? 32:24,"UInt")    ;dsBmih.biSize
    DllCall("GetObject", "UPTR", hBitmap, "int", A_PtrSize=8? 104:84, "UPTR", &DIBSECTION)
    hFile:=    DllCall("CreateFile", "UPTR", &sFile, "Uint", 0x40000000, "Uint", 0, "Uint", 0, "Uint", 2, "Uint", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "int64P", 0x4D42|14+40+(biSizeImage:=NumGet(DIBSECTION, A_PtrSize=8? 52:44, "UInt"))<<16, "Uint", 6, "UintP", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "int64P", 54<<32, "Uint", 8, "UintP", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "UPTR", &DIBSECTION + (A_PtrSize=8? 32:24), "Uint", 40, "UintP", 0, "Uint", 0)
    DllCall("WriteFile", "UPTR", hFile, "Uint", NumGet(DIBSECTION, A_PtrSize=8? 24:20, "UPtr"), "Uint", biSizeImage, "UintP", 0, "Uint", 0)
    DllCall("CloseHandle", "UPTR", hFile)
}

GetValidFilePath(filename)
{
    SplitPath, filename, , sDir, sExt, sName
    IfNotInString, sDir, :
        sDir = %A_ScriptDir%\%sDir%
    filename = %sDir%\%sName%.%sExt%
    StringReplace, filename, filename, \\, \, All
    return filename
}

;---------------------------------------------------------------
;    Struct List
;---------------------------------------------------------------
/*

typedef struct {
  DWORD   cbSize;
  DWORD   flags;
  HCURSOR hCursor;
  POINT   ptScreenPos;
} CURSORINFO, *PCURSORINFO, *LPCURSORINFO;

typedef struct _ICONINFO {
  BOOL    fIcon;
  DWORD   xHotspot;
  DWORD   yHotspot;
  HBITMAP hbmMask;
  HBITMAP hbmColor;
} ICONINFO, *PICONINFO;

typedef struct tagDIBSECTION {
  BITMAP           dsBm;
  BITMAPINFOHEADER dsBmih;
  DWORD            dsBitfields[3];
  HANDLE           dshSection;
  DWORD            dsOffset;
} DIBSECTION, *PDIBSECTION;

typedef struct tagBITMAPINFOHEADER {
  DWORD biSize;
  LONG  biWidth;
  LONG  biHeight;
  WORD  biPlanes;
  WORD  biBitCount;
  DWORD biCompression;
  DWORD biSizeImage;
  LONG  biXPelsPerMeter;
  LONG  biYPelsPerMeter;
  DWORD biClrUsed;
  DWORD biClrImportant;
} BITMAPINFOHEADER;

typedef struct tagBITMAP {
  LONG   bmType;
  LONG   bmWidth;
  LONG   bmHeight;
  LONG   bmWidthBytes;
  WORD   bmPlanes;
  WORD   bmBitsPixel;
  LPVOID bmBits;
} BITMAP, *PBITMAP;

typedef struct tagBITMAPINFO {
  BITMAPINFOHEADER bmiHeader;
  RGBQUAD          bmiColors[1];
} BITMAPINFO, *PBITMAPINFO;

typedef struct tagRGBQUAD {
  BYTE rgbBlue;
  BYTE rgbGreen;
  BYTE rgbRed;
  BYTE rgbReserved;
} RGBQUAD;

*/
}

sokalbr

Hi keka,

Thanks for this detailed response.

I just understand now, why there is literally no pixelbot actually (I already know autoit in 2012 and at this date, all the bot was on autoit), BC it's hard to search pixel.

That why the news bot like flaty or snow don't search pixel but read socket (I'm not sure) ; it's simplest.

Then I think I will try the first idea.

1. The script can recording the hexa color and convert it in reg I think (I will search but I think it's possible). For the spawn I will test your private server (<3)

2. If I record on the Dofus client directly, with the position and reg color, I thinks it's ok and I can know directly if the ressource is collectable with the white aura ??

3. If there is a monster the pixel is not the same ?? So there is no problem I think. And I can send shifts

And I have an other idea. When you send shift you can click on multiple ressources to farm it. Maybe you can just click on all the ressources position with shift. But so much wasted time ...

Thanks again.

Soka.

KekaBron

@sokalbr

I just understand now, why there is literally no pixelbot actually (I already know autoit in 2012 and at this date, all the bot was on autoit), BC it's hard to search pixel.

Yes, exactly.

That why the news bot like flaty or snow don't search pixel but read socket (I'm not sure) ; it's simplest.

Yeees bro, socket bots are better, the thing is if you modify something on the dofus files, mods can detect it, they compare the hash of the official files against your files, if its not a match, rip, banned. On my opinion, the safest bot would be a mix between a socket bot that gathers data from the maps, to know if a resource is up, to trace a route from point A to B etc, but the click/actions should be done as in a pixel bot, just sending clicks, not packets.

1. The script can recording the hexa color and convert it in reg I think (I will search but I think it's possible). For the spawn I will test your private server (<3)

Yes, I dont know with AutoIt, but with AutoHotKey you can record/check colors in hexa or rgb. My private server is the decayEmu 2.53, I think it is published here on this forum, also in dozenofelites etc. Just make sure to use an antivirus when u decompress the .zip because some people reuploaded it with trojans lmao.

2. If I record on the Dofus client directly, with the position and reg color, I thinks it's ok and I can know directly if the ressource is collectable with the white aura ??

Ammm, yes, I used to work with the white aura approach, but there are some problems. First, there are a lot of "interactive" things that have white aura. In the same map you can have doors, maybe a zaap, trees, fish, plants, mission objects...they all have the white aura... Another thing is that I dont remember if the white aura always have the same color... in darker areas or ligther areas is always the same? I dont know. So, to sum up, try it if you want but I'm not very optimistic about it xd.

3. If there is a monster the pixel is not the same ?? So there is no problem I think. And I can send shifts

If a monster is in front of a resource, your script wont find the resource, it wont click it, no problemo. The problem comes if you force the click, some people make pixel bots that always click on the resource, even if its not collectable, just because is simpler to code. Anyways sending the shift solves everything.

And I have an other idea. When you send shift you can click on multiple ressources to farm it. Maybe you can just click on all the ressources position with shift. But so much wasted time ...

Yes! there was a time when I used to do this, just go into a map, click on the 4 or 5 coordinates when the resources were, and wait. The thing is that for some resources, if they are collected, your click will be placed on an empty cell, and what happens when you click in an empty normal cell? your character moves to it. So basically your character will move from one cell to another, always close to the resources, which is not very "human" lol...and also it is a waste of time...

So yeah, the best choice for me is to not to search all over the screen, just record the places where I want to farm in each map, and always check if its collectable or not, so I dont waste too much time.

If u have any other questions feel free to ask. Also if u want the emulator, tell me, I think I can upload it to Google Drive.

Keka.

77Stein

Hello,

Before starting to explain my work, i would like to thank you very much Keka for your amazing job ! I start dev Bot for fun (in auto it) and your post are a great help :)

I'm using autoIt so it may be different with autoH.

The first thing i do when i start to develop is trying to understand informations provide by my cursor. I made this little script :

Func fSpy()
    journalMsg("________")
    $hCursor = _WinAPI_GetCursorInfo()
    journalMsg("Le curseur est : " & $hCursor[2])
    global $testHex
    $testhex=Hex($hCursor[2],8)
    journalMsg("Le curseur (v2) est : " & $testhex)
    journalMsg("il se trouver en : " & $hCursor[3] & "," & $hCursor[4])
    Local $iCursor = MouseGetCursor()
    Local $aArray = StringSplit("Hand|AppStarting|Arrow|Cross|Help|IBeam|Icon (obsolete)|No|Size (obsolete)|SizeAll|SizeNESW|SizeNS|SizeNWSE|SizeWE|UpArrow|Wait|Empty", "|", 2)
    journalMsg("CursorID = " & $iCursor )
    $vSuccesColor1 =PixelGetColor($hCursor[3],$hCursor[4])
    $testhex=Hex($vSuccesColor1 ,8)
    journalMsg("Couleur = " & $vSuccesColor1  & " Couleur Hex :  " & $testhex )
    FFSnapShot()
    $vSuccesColor1 = FFGetPixel(1902, 789,  $FFLastSnap)
    $testhex=Hex($vSuccesColor1,8)
    journalMsg("Couleur FF= " & $vSuccesColor1 & " FF HEx " & $testhex)

    journalMsg("________")


endFunc

Sorry its in french, i will rework all my code in english and part my script in multiple part (today it's a 1700+ lines file ^^').

doc getCursorInfo second argument catch the cursor so i thought it will be easy to check on hover if my ressource is collectable, and if it is , check 3s after if i collect it or not ( if not ==> have to move to my ressource). It works well during one week but it failed every week or month start. The cursor code change regulary ... I change my approach and try to follow your guide and pick 3 color of the ressource but with dark/light map zone i wasn't satisfy by the result. I try your last methode, in this post, to screen a part of the screen and check the change but it doesn't work very well in AutoIt.

Thanks to my cat i've seen an intersting thing with my spy runing every second : defaut dofus cursor is the Hand ( MouseGetCursor() ==> 0) and if you move hover a ressource wich disapear, your cursor will turn in Hand.

So i made this to collect cereal :

Func fFauche($vRessourceX,$vRessourceY,$vIdRessource)
    If $tPaysan[$vIdRessource] Then
        MouseMove($vRessourceX, $vRessourceY)
        sleep(500)



        $hCursor =  MouseGetCursor()


        ;journalMsg("Curseur : " &$hCursor)
        if $hCursor= -1 then    ;0x0A2D0995  0x3A980173 0x3E2C033F 0x0000000000660343 0x0000000000E50365
            MouseClick("left",$vRessourceX, $vRessourceY)
            While $vOkLoopRessource
            $hCursor = MouseGetCursor()
            If $hCursor = -1 Then   ;0x00010003  0x00010005 0x0000000000010003
                sleep(3000)
                ;journalMsg("Curseur dans la boucle: " &$hCursor)
                MouseMove($vRessourceX+2, $vRessourceY)
                MouseMove($vRessourceX, $vRessourceY)
            else
                $vOkLoopRessource = false
            EndIf

            WEnd
        endif

        $vOkLoopRessource = true
        _verifAggros()
        fCheckLevelUp()
        fCheckPods()
    EndIf

endFunc

Func fFauche($vRessourceX,$vRessourceY,$vIdRessource)

==> $vRessourceX,$vRessourceY i don't use MITM (packets) and i think it's out of my skills so i have to point every position ( the hardest part of the development to me, doing every map ..... sooooooo long x) )

==> $vIdRessource i make a table with every cereal and a binary information, if 1 take it else next step

First step is to move hover my ressource, get the information of my cursor and if it is collectable. Then move 2 pixel every 3s to check if it's ok (i've 'SHIFT' press before this function, may change it in my future code)

You can see all cursor code i collected (hexa code near my if).

At the end of my function i check if a fight start, if my job level up and my pods =)

I hope i have made this sufficiently clear.

I will rework my code next days, if you want i can post my development :)

Stein

KekaBron

@77Stein I'm happy that you could do your own code!

defaut dofus cursor is the Hand ( MouseGetCursor() ==> 0) and if you move hover a ressource wich disapear, your cursor will turn in Hand.

Yes! well done bro.

I will rework my code next days, if you want i can post my development

Sure! make a new post on the forum and share all your ideas, that way we can all benefit :^)

Keka.

RnBmMf9BDHrsLbv

I've reworked the code using the same idea but more in a more concise and clean way. Also it's written in hk2.

; Tries to get the current cusor image as a bitmap. It returns a Buffer containing the Bmp when succesful, otherwise False.
GetCursorBitMap() {
    ; https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-getcursorinfo
    CursorInfo := Buffer(24, 0)
    NumPut("UInt", CursorInfo.Size, CursorInfo)
    if DllCall("GetCursorInfo", "Ptr", CursorInfo) == False {
        return False
    }

    CursorFlags := NumGet(CursorInfo, 4, "UInt") ; flags
    IconHandle := NumGet(CursorInfo, 8, "Ptr") ; hCursor

    if CursorFlags != 1 {
        return False
    }

    ; https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-geticoninfo
    IconInfo := Buffer(32, 0)
    if DllCall("GetIconInfo", "Ptr", IconHandle, "Ptr", IconInfo) == False {
        return False
    }

    IconIsIcon := NumGet(IconInfo, 0, "Int") ; fIcon
    IconMaskBitMapHandle := NumGet(IconInfo, 16, "Ptr") ; hbmMask
    IconColorBitMapHandle := NumGet(IconInfo, 24, "Ptr") ; hbmColor

    ; https://learn.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getobject
    BmpMeta := Buffer(64, 0) ; https://learn.microsoft.com/en-us/windows/win32/api/wingdi/ns-wingdi-bitmap
    if DllCall("GetObject", "Ptr", IconColorBitMapHandle, "Int", BmpMeta.Size, "Ptr", BmpMeta) == False {
        return False
    }

    BmpWidth := NumGet(BmpMeta, 4, "Int")
    BmpHeight := NumGet(BmpMeta, 8, "Int")

    BmpFileHeaderSize := 14 ; https://learn.microsoft.com/en-us/windows/win32/api/wingdi/ns-wingdi-bitmapfileheader
    BmpInfoHeaderSize := 40 ; https://learn.microsoft.com/en-us/windows/win32/api/wingdi/ns-wingdi-bitmapinfoheader
    BmpDataSize := BmpWidth * BmpHeight * 4

    BmpBuffer := Buffer(BmpFileHeaderSize + BmpInfoHeaderSize + BmpDataSize, 0)
    NumPut("UInt", 0x4D42, BmpBuffer, 0) ; bfType
    NumPut("Short", BmpBuffer.Size, BmpBuffer, 2) ; bfSize
    NumPut("UInt", BmpFileHeaderSize + BmpInfoHeaderSize, BmpBuffer, 10) ; bfOffBits

    NumPut("UInt", BmpInfoHeaderSize, BmpBuffer, BmpFileHeaderSize + 0) ; biSize
    NumPut("Int", BmpWidth, BmpBuffer, BmpFileHeaderSize + 4) ; biWidth
    NumPut("Int", BmpHeight, BmpBuffer, BmpFileHeaderSize + 8) ; biHeight
    NumPut("Short", 1, BmpBuffer, BmpFileHeaderSize + 12) ; biPlanes
    NumPut("Short", 32, BmpBuffer, BmpFileHeaderSize + 14) ; biBitCount

    ; https://learn.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getbitmapbits
    if DllCall("GetBitmapBits", "Ptr", IconColorBitMapHandle, "Int", BmpDataSize, "Ptr", BmpBuffer.Ptr + BmpFileHeaderSize + BmpInfoHeaderSize) == 0 {
        return False
    }

    ; For the sake of simplicity this is only called in the happy path. So it
    ; leaks resources on errors.
    DllCall("DeleteObject", "Ptr", IconMaskBitMapHandle)
    DllCall("DeleteObject", "Ptr", IconColorBitMapHandle)

    return BmpBuffer
}

BufferEqual(Buf1, Buf2) {
    if Buf1.Size != Buf2.Size {
        return False
    }

    Int64Chunks := Buf1.Size // 8
    Int8Chunks := Mod(Buf1.Size, 8)

    Loop Int64Chunks {
        Chunk1 := NumGet(Buf1, (A_Index - 1) * 8, "Int64")
        Chunk2 := NumGet(Buf2, (A_Index - 1) * 8, "Int64")
        if Chunk1 != Chunk2 {
            return False
        }
    }

    Loop Int8Chunks {
        Chunk1 := NumGet(Buf1, Int64Chunks * 8 + A_Index - 1, "Char")
        Chunk2 := NumGet(Buf2, Int64Chunks * 8 + A_Index - 1, "Char")
        if Chunk1 != Chunk2 {
            return False
        }
    }

    return True
}